read only vraag

[xmir]

Allen,

Ik heb een excel bestand opgeslagen op een gedeelde server locatie. Dit bestand wordt door meerdere mensen geraadpleegd en bewerkt. Nu kan dat op dit moment alleen om de beurt omdat wanneer ik het bestand deel, er functies verloren gaan. Dat is op dit moment geen probleem maar er zijn mensen die het bestand graag open hebben staan zonder het te willen bewerken (zodat anderen niet geblokkeerd worden). Is het mogelijk een bestand bewust juist als read only te openen om zo anderen niet in de weg te zitten?
Het is een excel 2010 (xlsm) bestand.
Een mogelijkheid tot gelijktijdig bewerken zonder verlies van functies is er denk ik niet toch? Ik heb althans geen mogelijkheden gevonden.

Dank,

Mirjam

 

[spaarie]

Zoiets?

Private Sub Workbook_Open()
    If Not ThisWorkbook.ReadOnly Then
        If MsgBox("Bestand alleen lezen?", vbYesNo) = vbYes Then
            ThisWorkbook.ChangeFileAccess xlReadOnly
        End If
    End If
End Sub

Gelijktijdig bewerken gaat, voor zover ik weet, niet...

 

[snb]

In plaats van een bestand te openen kunnen ze er een kopie van maken:

Sub M_snb()
  workbooks.add "G:\OF\voorbeeld.xlxm"
end sub

 

[spaarie]

@snb: Nieuwe extensies?

 

[xmir]

Deze werkt niet...ik krijg geen melding als ik het bestand open na toevoeging van deze macro

Zoiets?

Private Sub Workbook_Open()
    If Not ThisWorkbook.ReadOnly Then
        If MsgBox("Bestand alleen lezen?", vbYesNo) = vbYes Then
            ThisWorkbook.ChangeFileAccess xlReadOnly
        End If
    End If
End Sub

Gelijktijdig bewerken gaat, voor zover ik weet, niet...

 

[spaarie]

Is het geopende bestand niet al alleen lezen? Dan zie je ook niks
Heb je de macro ook in ThisWorkbook staan?

Probeer dit anders

Private Sub Workbook_Open()
    If Not ThisWorkbook.ReadOnly Then
        If MsgBox("Bestand alleen lezen?", vbYesNo) = vbYes Then
            ThisWorkbook.ChangeFileAccess xlReadOnly
        End If
    Else
        MsgBox "Dit is al een alleen lezen bestand"
    End If
End Sub

 

[xmir]

Het bestand is niet read only maar ik had hem niet in ThisWorkbook staan. Nu heb ik al een macro in Thisworkbook staan:

Private Sub Workbook_Open()

  ISOweeknum = DatePart("ww", Date - Weekday(Date, 2) + 4, 2, 2)
  On Error GoTo met_maand
  Sheets("wk" & ISOweeknum).Activate
  
met_maand:
  Sheets(WorksheetFunction.Choose(Month(Date), "jan", "feb", "mrt", "apr", "mei", "juni", "juli", "aug", "sept", "okt", "nov", "dec") & " wk" & ISOweeknum).Activate
  
End Sub

Moet ik die van jou er op de een of andere manier tussen zetten?

 

[snb]

@Spaarie

Excel versie 2025a

 

[spaarie]

Je kan ze samenvoegen

Private Sub Workbook_Open()
    If Not ThisWorkbook.ReadOnly Then
        If MsgBox("Bestand alleen lezen?", vbYesNo) = vbYes Then
            ThisWorkbook.ChangeFileAccess xlReadOnly
        End If
    Else
        MsgBox "Dit is al een alleen lezen bestand"
    End If

ISOweeknum = DatePart("ww", Date - Weekday(Date, 2) + 4, 2, 2)
    On Error GoTo met_maand
        Sheets("wk" & ISOweeknum).Activate
  
met_maand:
  Sheets(WorksheetFunction.Choose(Month(Date), "jan", "feb", "mrt", "apr", "mei", "juni", "juli", "aug", "sept", "okt", "nov", "dec") & " wk" & ISOweeknum).Activate
End Sub

Of een module maken en in je Workbook_Open event de macro aanroepen
ThisWorkbook:

Private Sub Workbook_Open()
    Call alleen_lezen
ISOweeknum = DatePart("ww", Date - Weekday(Date, 2) + 4, 2, 2)
    On Error GoTo met_maand
        Sheets("wk" & ISOweeknum).Activate
  
met_maand:
  Sheets(WorksheetFunction.Choose(Month(Date), "jan", "feb", "mrt", "apr", "mei", "juni", "juli", "aug", "sept", "okt", "nov", "dec") & " wk" & ISOweeknum).Activate
End Sub

Module:

Sub alleen_lezen()
    If Not ThisWorkbook.ReadOnly Then
        If MsgBox("Bestand alleen lezen?", vbYesNo) = vbYes Then
            ThisWorkbook.ChangeFileAccess xlReadOnly
        End If
    Else
        MsgBox "Dit is al een alleen lezen bestand"
    End If
End Sub

 

[xmir]

Jesssss dit is wat ik zoek! Dank!

 

[snb]

Private Sub Workbook_Open()
    On Error resume next
    alleen_lezen

    ISOweeknum = DatePart("ww", Date - Weekday(Date, 2) + 4, 2, 2)
    application.goto Sheets("wk" & ISOweeknum).cells(1)
    application.goto Sheets(format(date,"mmm") & " wk" & ISOweeknum).cells(1)
End Sub