Sorteren en voorwaardelijke opmaak als opdrachtknop

[Didelpara]

Beste,

Er wordt een excel bestand gegenereerd door een programma en op dit werkblad staan gegevens in kolommen

opdracht 1:
twee kolommen op dit werkblad zouden uitgebreid moeten gesorteerd worden:
als eerste de kolom met de uren daarna de kolom met tafels als tweede (de uren en tafels staan altijd in dezelfde kolom)

opdracht 2:
na het sorteren zou in de kolom met de uren, alle zelfde uren gekleurd moeten worden (kleur maakt niet uit).

Dit alles kan uiteraard gedaan worden via voorwaardelijke opmaak en sorteren maar is het mogelijk deze 2 opdrachten via een knop in de werkbalk te zetten zodanig dat wanneer er de volgende dag een ander rapport gegenereerd wordt dit gewoon via een druk op de opdrachtknop(pen) kan gedaan worden? Dit zal dus in excel als invoegtoepassing moeten gezet worden vermoed ik?

voorbeeld: Bekijk bijlage Report.xlsb

 

[Timshel]

Probeer het eens met deze macro:

Sub tsh()
    Dim i As Long
    
    Application.ScreenUpdating = False
    Cells.UnMerge
    With Range("I10")
        .Formula = "=TRIM(LEFT(H10,LEN(H10)-2)) & TEXT(TRIM(RIGHT(H10,2)),""00"")"
        .AutoFill Range("I10:I" & Cells(Rows.Count, 7).End(xlUp).Row)
    End With
    With Cells(10, 1).CurrentRegion
        .Sort [G10], xlAscending, [I10], , xlAscending, , , xlNo
        .Columns(9).ClearContents
        Range("G10:H10").Font.Color = 1
        For i = 1 To .Rows.Count
            If Range("G10").Offset(i - 1) = Range("G10").Offset(i - 2) Then
                Range("G10:H10").Offset(i - 1).Font.Color = Range("G10:H10").Offset(i - 2).Font.Color
            Else
                Range("G10:H10").Offset(i - 1).Font.Color = RGB(Int(Rnd() * 255), Int(Rnd() * 255), Int(Rnd() * 255))
            End If
        Next
    End With
    Application.ScreenUpdating = True
End Sub

Toelichting: de macro sloopt onomkeerbaar de samengevoegde cellen uit het werkblad. Je kunt een invoegtoepassing van maken de macro of hem toevoegen aan je persoonlijke werkmap.

 

[Didelpara]

Timshel,

Bedankt voor de reply.
Ik ga dit morgen testen op het werk.

Alvast bedankt.

 

[Didelpara]

Timshel,

ik moet het nog verder testen maar ik denk dat die het doet, thank you!.