Stuk tekst uit een celinhoud halen

[ongenae]

Hallo Allen

Ik zit met een iets wat complex probleem.
Ik wil namelijk een stuk tekst uit een celinhoud halen en in een andere kolom plaatsen, met name het nummer tussen de haakjes.

ES 200 Mini-Drive-Unit ES 200 (04000061) -------------- 04000061

Dit is eenvoudig, hiervoor gebruik ik onderstaande formule

=ALS(A1="";"";(LINKS((RECHTS(A1;(LENGTE((A1))-(VIND.SPEC("(";A1)))));LENGTE((RECHTS(A1;(LENGTE((A1))-(VIND.SPEC("(";A1))))))-1)))

Echter is mijn probleem dat er andere artikels zijn met ( ) in de omschrijving

ES 200 Mini-Drive-Unit ES 200 (04000061)-------------- 04000061
ES 200 MOTOR (AT) (9925511801150) -------------- AT) (9925511801150
ES 90/100 LOOPROL (4 ST (18018409150) -------------- 4 ST (18018409150
VLOERGELEIDER L MODEL ( (32609502150) -------------- (32609502150


in feit zou hij altijd van achteren uit moeten beginnen werken en zoeken naar het eerste ( dat hij tegenkomt.

Kan iemand mij hierbij helpen,
Hartelijk dank

 

[rebmog]

Probeer deze matrixformules eens (ingeven met Ctrl+Shift+Enter):

=DEEL(A1;MAX(ALS((DEEL(A1;RIJ(INDIRECT("1:"&LENGTE(A1)));1))="(";RIJ(INDIRECT("1:"&LENGTE(A1)))))+1;LENGTE(A1)-MAX(ALS((DEEL(A1;RIJ(INDIRECT("1:"&LENGTE(A1)));1))="(";RIJ(INDIRECT("1:"&LENGTE(A1)))))-1)

 

[arrie23]

Met behulp van een User Defined Function (UDF):

Onderstaande invoeren in een module in VBE (Via alt F11)

Function Nummer_haakje(tekst)
   Nummer_haakje = Mid(tekst, InStrRev(tekst, "(") + 1, (InStrRev(tekst, ")") - InStrRev(tekst, "(")) - 1)
End Function

Nu is de formule "Nummer_haakje" toegevoegd aan de formulelijst onder "door gebruiker gedefinieerd".
=Nummer_haakje(A1) levert dan dus 04000061 als uitkomst van de formule

 

[popipipo]

=TRIM(RIGHT(SUBSTITUTE(LEFT(A2;LEN(A2)-1);"(";REPT(" ";255));255))

Hier nog een mogelijkheid.

 

[ongenae]

Super, bedankt allemaal.

 

[alixaelterman]

Tekst uit cel halen

Hi,

Kan iemand mij verder helpen?
Ik had graag uit een cel, zowel de naam gekopieerd naar een andere cel, alsook het emailadres : Anne Boels,"boelsanne@gmail.com","","Generic","","","","","","","","","","",
Loïc Aelterman,"loicaelterman@hotmail.com","","Generic","","","","","","","","","","",

Alle andere zaken heb ik niet nodig. Dus alle namen hebben verschillende lengte en er zijn meerdere "", waar iets tussenstaat. Ik heb enkel het emailadres nodig uit de eerste "".
Iemand een idee?

Groetjes,
Alix

 

[spaarie]

Alix,
Je 'boycot' nu iemand anders zijn topic. Voortaan zou je een eigen topic moeten maken en verwijzen naar deze als voorbeeld.

=SPATIES.WISSEN(DEEL(SUBSTITUEREN($A1;"""";HERHALING(" ";999));2*KOLOMMEN($A:A)*999-998;999))