Tabel omzetten

[bvanbaal]

Hallo Excell'ers,

Ik heb een vraag met betrekking tot het omzetten van tabellen. Het probleem is als volgt:
Voor de hockeyvereniging heb ik een wedstrijdschema gemaakt om op maandagavond te hockeyen. Hiervan moet ik de score ook bijhouden. Dit doe ik door handmatig de score op te schrijven en dinsdags ze uit te werken in Excel. In het bijgevoegd bestand heb ik alles kort uitgewerkt. Hier staan maar een aantal teams en tijden, normaal gesproken zijn dit er veel meer.
De rode tabel is het wedstrijdschema waarin ik handmatig de scores bij schrijf. Nu wil ik dat de stand automatisch berekend wordt in de blauwe tabel. Nu denk ik dat dit het makkelijkst is door de scores overzichtelijk weer te geven in de groene tabel, alleen wil ik niet steeds handmatig de scores 2x in moeten vullen. Hier moet Excel een oplossing voor hebben.
De gele tabel berekent het aantal punten (3 voor winst, 1 voor gelijk, 0 voor verlies) aan de hand van de groene tabel.

Dus mijn vraag: is er een makkelijke manier om de scores uit de rode tabel automatisch aan de groene tabel toe te voegen? En andere tips&tricks om de tabel te vereenvoudigen zijn natuurlijk ook van harte welkom .

Bekijk bijlage Wedstrijdschema omrekenen.xlsx
ps. Waarom "+", "-" en "saldo" de waarde "#WAARDE" geven is mij nu niet helemaal duidelijk, maar ook niet echt van belang op dit moment.

 

[jffry101]

Ik neem aan dat alle 30 wedstrijden die avond gespeeld worden?

Zijn het altijd 6 teams of verschilt dit ook?

 

[arrie23]

Ik heb een oplossing waarbij ik geen gebruik maak van de groene en gele tabel maar van 2 hulpkolommen aan de rode tabel. Deze hulpkolommen bevatten een formule met voor team 1 en team 2 de score per wedstrijd obv de uitslag (3= gewonnen, 1=gelijk, 0 = verloren). Deze hulpkolommen en de bestaande info in de rode tabel worden vervolgens gebruikt om de blauwe tabel te vullen mbv een aantal verschillende SOMPRODUCT-formules
Probleem:
Ik kan vanaf hier geen bijlage toevoegen (heb hier een hele oude Explorer-versie en de website loopt compleet vast). Is er een andere manier om deze oplossing bij je te krijgen? Anders krijg je 'm vanavond als ik thuis ben

 

[arrie23]

Zoals beloofd
Bekijk bijlage Wedstrijdschema omrekenen.xlsx

 

[bvanbaal]

jffry101: Het zijn in totaal 11 teams, en alle 30 wedstrijden worden inderdaad op één avond gespeeld.

Dank arrie23 voor je bijdrage. De SOMPRODUCT-formule is een handige aanvulling.

Maar omdat het dus een groot aantal wedstrijden betreft en de scores overzichtelijk op een website geplaatst moeten worden, zou ik graag zien dat de scores automatisch in de groene kolom geplaatst worden.

Is het mogelijk om twee argumenten te gebruiken voor het invullen van 1 cel? Ik probeer het in formules te vertalen, al weet ik dat dit niet juist is:

ALS kolom C = Team A EN ALS kolom D = Team B,
DAN kolom N = kolom E

Ik heb andere schema's bekeken en zij werkten met de formule verticaal zoeken en ook met macro's, maar dat snap ik niet helemaal.

 

[arrie23]

Verwijder uit de groene tabel eerst de samenvoegingen van de cellen van Team A tegen Team A, B tegen B etc. Maak er weer gewoon losse cellen van.

Zet in cel K6 deze formule:
=SOMPRODUCT(($C$5:$C$15=$J6)*($D$5:$D$15=K$2)*($E$5:$E$15))
Trek door naar beneden
Kopieer naar kolom N, Q, T, W, Z

Zet in cel M6 deze formule:
=SOMPRODUCT(($C$5:$C$15=$J6)*($D$5:$D$15=K$2)*($F$5:$F$15))
Trek door naar beneden
Kopieer naar kolom P,S, V, Y, AB

In de cellen van team A tegen team A, B tegen B etc kun je de formules weer verwijderen, de cellen weer netjes opmaken en eventueel weer samenvoegen.
Waar nodig de tabelopmaak weer wat fatsoeneren

 

[bvanbaal]

Wow, bedankt arrie23! Scheelt een hoop werk!

 

[sylvester-ponte]

zonder hulp kolom en ook direct naar die blauwe

 

[bvanbaal]

Ik heb toch nog een kleine vraag:
Het echte wedstrijdschema omvat 12 competitieweken, daarvoor is het schema al gemaakt, maar zijn de doelpunten (uiteraard) nog niet ingevuld. Maar als ik de SOMPRODUCT-formule hierin doortrek, dan krijg ik de melding #WAARDE. Enig idee hoe dit kan? En hoe dit op te lossen is?

Bekijk bijlage Wedstrijdschema omrekenen.xlsx

 

[ExcelAmateur]

Ik weet niet welke versie je van Excel gebruikt?
Kijk eens of je wat kunt ALS.FOUT(SOMPRODUCT(

 

[arrie23]

Het gaat mis omdat je de kolomkoppen herhaalt. In de matrix met doelpunten van de thuispartij: E5:E30 staat nu ook een keer Doelpunten (ook nog eens als samengevoegde cel: voorkom dit zoveel mogelijk!!) en Team 1. Dit is tekst en daar kan Excel niet mee rekenen. Is het nodig om dat schema inclusief kolomkoppen steeds op deze manier te herhalen of kan het hele schema ook in 1 tabel zonder herhalende kolomkoppen.

Ook moet je sowieso Q$2 veranderen in Q$5. Cel Q6:
=SOMPRODUCT(($C$5:$C$30=$P6)*($D$5:$D$30=Q$5)*($E$5:$E$30))

Verwijder na bovenstaande aanpassing dan eens de kolomkoppen van rij 18 en 19

 

[sylvester-ponte]

rode cijfers aangepast (let op je hebt wat spelfouten in de team namen zitten)

 

[arrie23]

Zonder aanpassingen aan je bestand

Cel Q6:
=SOMPRODUCT(--($C$5:$C$30=$P6);--($D$5:$D$30=Q$5);(--ISGETAL($E$5:$E$30));($E$5:$E$30))

Cel S6:
=SOMPRODUCT(--($C$5:$C$30=$P6);--($D$5:$D$30=Q$5);(--ISGETAL($F$5:$F$30));($F$5:$F$30))

 

[arrie23]

Als je nog onderscheid wil maken in wedstrijden die niet in het schema staan of waar nog geen score voor bekend is:

LET OP: In cel C20 staat teamB (zonder spatie) ipv team B (met spatie)

Cel Q6:
=ALS(SOMPRODUCT(--($C$5:$C$30=$P6);--($D$5:$D$30=Q$5))=0;"niet in schema";ALS(SOMPRODUCT(--($C$5:$C$30=$P6);--($D$5:$D$30=Q$5);(--ISLEEG($E$5:$E$30)))=1;"nog geen score";SOMPRODUCT(--($C$5:$C$30=$P6);--($D$5:$D$30=Q$5);(--ISGETAL($E$5:$E$30));($E$5:$E$30))))

Cel S6:
=ALS(SOMPRODUCT(--($C$5:$C$30=$P6);--($D$5:$D$30=Q$5))=0;"niet in schema";ALS(SOMPRODUCT(--($C$5:$C$30=$P6);--($D$5:$D$30=Q$5);(--ISLEEG($F$5:$F$30)))=1;"nog geen score";SOMPRODUCT(--($C$5:$C$30=$P6);--($D$5:$D$30=Q$5);(--ISGETAL($F$5:$F$30));($F$5:$F$30))))