Opgelost Tekst groeperen in Power editor

[moensk]

In bijlage een voorbeeld.
aan de hand van kolom "key" dient er gegroepeerd te worden, moeilijkheid is dat het te groeperen veld "MOB" een tekst veld is.
hij moet alles codes samen in één veld zetten in één rij.

 

[JEC.]

Dit is voldoende

let
    Source = Excel.CurrentWorkbook(){[Name="Test"]}[Content],
    grp = Table.Group(Source, {"Losnaam", "Postcode", "Gemeente", "Key"}, {{"Mob", each Text.Combine(_[Mob]," - ")},{"pp", each _[pp]{0}}})
in
    grp

 

[moensk]

Jec - thanks, werkt goed
in een latere stap moet ik in de nieuwe cel kijken en als er een "W" of een "A" in staat moet waarde "0" zijn.
hieronder hoe ik het had voordat ik groepeerde op MOB maar nu dus zou moeten aangepast worden,
graag even kijken aub

= Table.AddColumn(#"WT_JA of NEE", "WACHTTIJD", each if ([MOB] = "W" or [MOB] = "A") then 0 else if ((([WT_TOTAAL] / [PP_LOSKEY]) * [PP]) < 0.000069) then 0 else ([WT_TOTAAL] / [PP_LOSKEY]) * [PP])

 

[JEC.]

= Table.AddColumn(Source, "WACHTTIJD", each if List.ContainsAny(Text.ToList([MOB]),{"A","W"}) then 0 else 1)

 

[moensk]

JEC,
kleine bijlage gemaakt, wilt ge even kijken waarom hij samenvoegen niet wilt doen
ik krijg het niet gevonden

 

[JEC.]

Je groepeert op alle kolommen. Zo is iedere regel uniek, en zal er nergens een groepering plaatsvinden.

 

[JEC.]

let
    Bron = Excel.CurrentWorkbook(){[Name="DATA__2"]}[Content],
    grp = Table.Group(Bron, {"OPDRACHT"} , {"MOB_SAMEN", each Text.Combine(_[MOB]," - ")}),
    merge = Table.NestedJoin(grp, {"OPDRACHT"}, Table.Distinct(Bron, {"OPDRACHT", "SOORT"}), {"OPDRACHT"},"tbl", JoinKind.LeftOuter),
    cols = List.Skip(Table.ColumnNames(Bron),1),
    result = Table.ExpandTableColumn(merge, "tbl", cols,cols)
in
    result

 

[moensk]

thanks - simpel antwoord - maar duidelijk genoeg om de oplossing te vinden
ik haalde in de lijst "MOB" weg en hij deed het ook

 

[JEC.]

Als de regels voor de rest niet meer verschillen is dat ook voldoende inderdaad

 

[moensk]

JEC, vraagje waarom een "_" bij Text.Combine(_[MOB]... ? kunt ge dat even verduidelijken aub

 

[JEC.]

Als je each gebruikt, is _ de variabele. Bij een each hoort een "_", waarbij deze steeds de nieuwe regel representeert.
In dit geval zou je het weg kunnen laten overigens.


Zet bijvoorbeeld dit maar eens in een lege query

let
    xList = List.Transform({1..10}, each _ * 2) 
in
    xList

En dit zou je ook weer zo kunnen schrijven

xList = List.Transform({1..10}, (x)=> x * 2)

 

[moensk]

oke - nu duidelijk
thanks