Tellen hoe vaak een reeks getallen voorkomt

[Youri92]

Ik ben met een project voor werk bezig en wil graag scores tellen en hoe veel mensen een bepaalde score hebben

Nu ziet mijn tabel er zo uit

Naam score1 score2 score3
Ben 100 90 100
Jim 100 100 100
Tim 100 100 100

Nu wil ik tellen hoe vaak iemand bij alle kolommen een score van 100 heeft, in dit geval dus 2 personen

 

[Timshel]

Ik kom uit op deze:

=SOMPRODUCT(--(SUBTOTAAL(9;VERSCHUIVING(B2;RIJ(1:30)-1;;;AANTALARG(1:1)-1))/(AANTALARG(1:1)-1)=100))

 

[HSV]

Knap bedacht @Timshel.

 

[E v R]

nog eentje:

=SUMPRODUCT(--(MMULT(B2:D6;{1;1;1})=SUM({1;1;1})*100))

 

[HSV]

Ik wil beide oplossingsaanbieders niet teleurstellen, maar een testje gaf aan dat beide formules niet vlekkeloos werken.

80 120 100 geeft helaas ook resultaat.

Dus mijn reactie was even te vroeg.

 

[E v R]

Goed gezien Harry,

Denk dat we beiden er vanuit zijn gaan dat 100 de maximale score is...

 

[HSV]

@E v R,

Och, het kan best de goedkeuring krijgen natuurlijk, maar ik dacht ik meld het maar even om te kijken naar andere oplossingen.
Ik zag in een testje van jouw formule dat ik het scheidingsteken "\" moest gebruiken in de eerste matrix en niet in de tweede, wat mij uiteraard verbaasde.
Ook moet de formule precies op het bereik passen.
Ik heb het iets kunnen inkorten maar die hoef ik niet meer te plaatsen.
Ik zal ook nog eens wat proberen te knutselen (is nu wel een uitdaging).

 

[E v R]

nieuwe poging:

=SUMPRODUCT(--(MMULT((B2:D6=100)/3;{1;1;1})=1))

ipv die {1;1;1} of met \ kan eventueel ook

TRANSPOSE(COLUMN(B2:D6)^0)

om het direct aan het bereik te koppelen, maar dan wel afsluiten met CTRl+Shift+Enter

 

[HSV]

Dat heb je snel geflikt.
In mijn versie ziet het er zo uit.

=SOMPRODUCT(--(PRODUCTMAT((B2:D6=100)/3;{1\1\1})=1))

Mijn complimenten. :thumb:

Ps. de somproduct kan je nog veranderen in som.

 

[E v R]

Thanks,

=SOMPRODUCT(--(PRODUCTMAT((B2:D6=100)/3;transponeren(kolom(b2:d6))=1))

afsluiten als matrix werkt bij jou ook?

die ; versus \ zal wel een regio instelling oid zijn..

 

[HSV]

Ja, die gaat ook goed. :thumb:
Heb je mijn 'Ps.' nog gelezen in mijn vorig schrijven.

 

[Timshel]

Ik moest de formule zo maken om het pratend te krijgen:

=SOM(--(PRODUCTMAT((B2:D30=100)/3;RIJ(1:3)^0)=1))

Nog een variant van mijn eigen brouwsel:

={SOM(ALS.FOUT(SUBTOTAAL(1;VERSCHUIVING(B2;RIJ(1:30);;;AANTALARG(1:1)-1))=100;0)*ALS.FOUT(SUBTOTAAL(7;VERSCHUIVING(B2;RIJ(1:30);;;AANTALARG(1:1)-1))=0;0))}

 

[E v R]

Heb je mijn 'Ps.' nog gelezen in mijn vorig schrijven.

Yep:thumb: @Tim inderdaad met die ^0 om er 1-tjes van te maken (vergeten over te typen in NL-formule), jouw (wat langere) formule werkt ongeacht de systeeminstellingen in 1 keer

 

[rebmog]

Hoewel ik de formule met PRODUCTMAT fraai vind, hier nog een andere variant:

=SOM(--(AANTAL.ALS(VERSCHUIVING(B1:D7;RIJ(1:7)-1;0;1;3);100)=3))

 

[Youri92]

=SOMPRODUCT(--(PRODUCTMAT((B26=100)/3;{1\1\1})=1))

Deze werkt, bedankt.
Nu een volgende vraag als toevoeging ik heb nu meerdere bereiken waaruit ik dezelfde info wil halen

Het ziet er dus zo uit

Jim 90 100 100 - 100 100 100
Ben 100 100 100 - 100 100 100
Tim 100 100 100 - 100 100 100

In dit geval wil ik uit beide bereiken reken hoeveel iemand op alles 100 heeft hier mowt dus 2 uitkomen in dit geval

 

[Ginger]

Ik zou persoonlijk met een hulpkolom naast je uitslagen gaan werken. Met een formule als
=aantal(A2:f2)=aantal.als(A2:f2;100)
Dit geeft waar of onwaar. En die kan je dan heel simpel optellen...