Hallo Danny,
De formule kan denk ik niet korter.
HTML:
INTEGER(((RIJ()-3)/($A$1/2+2)))=(((RIJ()-3)/($A$1/2+2)))
Deze formule is toch ALTIJD WAAR ?
Waarom niet 1=1
Stel de formule staat op rij 32 en in A1 staat de waarde 6. Dan geeft RIJ() de waarde 32, ($A$1/2+2) geeft dan 6/2 + 2 en dat resulteert in 5.
(((RIJ()-3)/($A$1/2+2))) levert dan 32/5 is 6,4 op.
INTEGER(((RIJ()-3)/($A$1/2+2))) geeft INTEGER(6,4) en dat geeft 6. En 6 is niet gelijk aan 6,4.
Door gebruik te maken van de functie RIJ() kun je de formule gemakkelijk kopieren.
Zou je vaste waardes in de formules zetten dan moet je die in iedere cel handmatig aanpassen als je de formules kopieert.
RIJ()-3 wordt er genomen omdat je wellicht drie kopregels hebt boven de eerste rij waarin de formule staat.
Door de vaste waardes 189, 74 etc in de formules te zetten maak je het sheet inflexibel: De waarde in A1 zorgt voor die flexibiliteit. Wat is er dan flexibel gemaakt: wel je werkt nu in blokken die zich herhalen en A1 bepaalt de lengte van die blokken.
Nog even de uitwrking voor jouw tweede formule:
=ALS(ISGETAL(INDIRECT(ADRES(RIJ()-($A$1/2+2)*(INTEGER((RIJ()-3)/($A$1/2+2)))+($A$1/2-3)*12-1;INTEGER(((RIJ()-3)/($A$1/2+2)))*2+1;;;"wedstrijdschema's")));ALS(RIJ()>($A$1-1)*($A$1/2+2)+2;"";INDIRECT(ADRES(RIJ()-($A$1/2+2)*(INTEGER((RIJ()-3)/($A$1/2+2)))+($A$1/2-3)*12-1;INTEGER(((RIJ()-3)/($A$1/2+2)))*2+1;;;"wedstrijdschema's")));"")
De kern is ook hier een ALS-functie. De argumenten zijn:
Logische voorwaarde:
ISGETAL(INDIRECT(ADRES(RIJ()-($A$1/2+2)*(INTEGER((RIJ()-3)/($A$1/2+2)))+($A$1/2-3)*12-1;INTEGER(((RIJ()-3)/($A$1/2+2)))*2+1;;;"wedstrijdschema's")))
De kern van deze formule is de functie ISGETAL. Daarmee wordt de logische voorwaarde terug gebracht tot de voorwaarde is de inhoud van een bepaalde cel een getal of niet. De betreffende cel wordt gevonden door middel van de formule
INDIRECT(ADRES(RIJ()-($A$1/2+2)*(INTEGER((RIJ()-3)/($A$1/2+2)))+($A$1/2-3)*12-1;INTEGER(((RIJ()-3)/($A$1/2+2)))*2+1;;;"wedstrijdschema's"))
Uitleg van deze formule is conform de uitleg bij jouw eerste formule (zie mijn vorige bericht).
Wellicht ten overvloede: door het gebruik van de functie RIJ() wordt er een celadres geformeerd dat afhankelijk is van het rijnummer van de cel waarin deze formule staat.
Waarde als onwaar: "" , dus een lege cel
Waarde als waar:
ALS(RIJ()>($A$1-1)*($A$1/2+2)+2;"";INDIRECT(ADRES(RIJ()-($A$1/2+2)*(INTEGER((RIJ()-3)/($A$1/2+2)))+($A$1/2-3)*12-1;INTEGER(((RIJ()-3)/($A$1/2+2)))*2+1;;;"wedstrijdschema's")))
Ook nu is er weer sprake van een ALS-functie:
Logische voorwaarde: RIJ()>($A$1-1)*($A$1/2+2)+2
Waarde als waar: ""
Waarde als on-waar:
INDIRECT(ADRES(RIJ()-($A$1/2+2)*(INTEGER((RIJ()-3)/($A$1/2+2)))+($A$1/2-3)*12-1;INTEGER(((RIJ()-3)/($A$1/2+2)))*2+1;;;"wedstrijdschema's"))
In de ADRES-functies wordt in het eerste argument een RIJGETAL berekent, afhankelijk van het rijnummer van de cel,waarin de formule staat. Zo worden er ook in het tweede argument een KOLOMGETAL berekent. Doordat het argument ABSOLUUT_GETAL niet is ingevuld wordt er een absoluut adres gemaakt. Doordat het argument A1 niet is ingevuld wordt er een adres in de vormA1 aangemaakt (bijv bij een kolomgetal 5 en een rijgetal 3 wordt het adres E3). De invulling van het argument Tekst betekent dat verwezen wordt naar de cel op het tabblad met de naam in het argument Tekst.
Het resultaat van de functie ADRES zou dus bijv kunnen zijn 'wedstrijdschema''s'!$E$3.
Het is een heel verhaal geworden en ik hoop dat het je een beetje duidelijker is geworden.
Ik moet je wel even zeggen dat ik deze gehele verklaring geef vanuit de formules, zonder dat ik ze in een sheet geplaatst zie. Ik hoop dan ook dat als jij ze wel in het sheet ziet dat met name mijn opmerking over die blokken correct zal blijken.
Groeten vanuit Apeldoorn
