unieke waarden uit kolom filteren met VBA

[HenkQ]

Goedemorgen,

Ik vind van alles op het gebied van unieke waarden uit een kolom filteren, echter niet mijn specifieke situatie.


Wat ik wil is uit kolom C alle unieke waarden filteren en dan opslaan in een VBA-variabele als tekst met een / tussen de waarden, dus niet op het werkblad.




Wie heeft hier een regeltje code voor?

Alvast bedankt.

 

[VenA]

Bv

Sub VenA()
  ar = Cells(1, 3).CurrentRegion
  For j = 1 To UBound(ar)
    If InStr(c00, ar(j, 1)) = 0 Then c00 = c00 & "/" & ar(j, 1)
  Next j
  Debug.Print Mid(c00, 2)
End Sub

 

[HenkQ]

Super!

Dankjewel.

 

[Enigmasmurf]

"Super" of "bijna super", that's the question.
Mij lijkt het nuttiger ook "/" mee op te nemen in de zoektekst, want nu zal, en ik verzin zo maar wat, als eerst "Freddy" is toegevoegd aan c00, en daarna "Fred" wordt aangetroffen, deze laatste niet worden toegevoegd. En dat is met grote waarschijnlijkheid toch de bedoeling (?)

 

[VenA]

Da's wel een goede @Enigmasmurf alleen maak ik code obv voorbeeldjes en niet op mogelijk omissies in niet geplaatste voorbeeldbestanden

Alternatief al moet het volgens mij ook direct met Filter kunnen dus zonder loop.

Sub VenA()
  ar = Cells(1, 3).CurrentRegion
  With CreateObject("Scripting.Dictionary")
    For j = 1 To UBound(ar)
      .Item(ar(j, 1)) = ""
    Next j
    c00 = Join(Application.Index(.keys, 0, 0), "/")
  End With
  Debug.Print c00
End Sub

 

[Enigmasmurf]

alleen maak ik code obv voorbeeldjes

VenA, da's ook een oplossing, natuurlijk.
Zelf ben ik eerder van het principe dat een voorbeeld maar een voorbeeld is :d
Alternatief stukje code dat op de eerst ingeslagen weg verder gaat:

Sub enigmasmurf()
  ar = Cells(1, 3).CurrentRegion
  c00 = "/" & ar(1, 1) & "/"
  For j = 2 To UBound(ar)
    If InStr(c00, "/" & ar(j, 1) & "/") = 0 Then c00 = c00 & ar(j, 1) & "/"
  Next j
  Debug.Print Mid(c00, 2, Len(c00) - 2)
End Sub

 

[VenA]

Alternatief stukje code dat op de eerst ingeslagen weg verder gaat:

Dat had je al vermeld vandaar het alternatief.

Gaat zo ook wel goed denk ik.

If InStr(c00, ar(j, 1) & "/") = 0 Then c00 = c00 & "/" & ar(j, 1)

tenzij iemand /Fred of /Fred/ of wat jij maar verzinnen wil heet.

 

[HSV]

c00 = Join(.keys, "/")