vba code aanpassen

[tonsie]

Hallo ik heb een vraagje over vba ik heb een vba code die een pagina van een excel sheet doet mailen maar ik zou graag bij BCC
verwijzen naar een mailadres dat op blad1 in cel a12 staat kan dit ?????

 

[Joske2000]

Ja,

Zet eventjes een voorbeeldje erbij, dat praat makkelijker

Thx,

Joske

 

[tonsie]

het gaat om de volgende code en met name het gedeelte wat in te vullen bij BCC zodat hij verwijst naar blad 1 cewl a12

Sub Mail_ActiveSheet()
'Working in 2000-2007
Dim FileExtStr As String
Dim FileFormatNum As Long
Dim Sourcewb As Workbook
Dim Destwb As Workbook
Dim TempFilePath As String
Dim TempFileName As String
Dim OutApp As Object
Dim OutMail As Object

With Application
.ScreenUpdating = False
.EnableEvents = False
End With

Set Sourcewb = ActiveWorkbook

'Copy the sheet to a new workbook
ActiveSheet.Copy
Set Destwb = ActiveWorkbook

'Determine the Excel version and file extension/format
With Destwb
If Val(Application.Version) < 12 Then
'You use Excel 97-2003
FileExtStr = ".xls": FileFormatNum = -4143
Else
'You use Excel 2007
'We exit the sub when your answer is NO in the security dialog that you only
'see when you copy a sheet from a xlsm file with macro's disabled.
If Sourcewb.Name = .Name Then
With Application
.ScreenUpdating = True
.EnableEvents = True
End With
MsgBox "Your answer is NO in the security dialog"
Exit Sub
Else
Select Case Sourcewb.FileFormat
Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
Case 52:
If .HasVBProject Then
FileExtStr = ".xlsm": FileFormatNum = 52
Else
FileExtStr = ".xlsx": FileFormatNum = 51
End If
Case 56: FileExtStr = ".xls": FileFormatNum = 56
Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
End Select
End If
End If
End With

' 'Change all cells in the worksheet to values if you want
' With Destwb.Sheets(1).UsedRange
' .Cells.Copy
' .Cells.PasteSpecial xlPasteValues
' .Cells(1).Select
' End With
' Application.CutCopyMode = False

'Save the new workbook/Mail it/Delete it
TempFilePath = Environ$("temp") & "\"
TempFileName = "Part of " & Sourcewb.Name & " " & Format(Now, "dd-mmm-yy h-mm-ss")

Set OutApp = CreateObject("Outlook.Application")
OutApp.Session.Logon
Set OutMail = OutApp.CreateItem(0)

With Destwb
.SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
On Error Resume Next
With OutMail
.To = "j.senden@wml.nl"
.CC = "l.geurts@wml.nl"
.BCC = ""
.Subject = "afroep/extra/retourmateriaal"
.Body = "M.vr.gr. Westvoort"
.Attachments.Add Destwb.FullName
'You can add other files also like this
'.Attachments.Add ("C:\test.txt")
.Display 'or use .Send
End With
On Error GoTo 0
.Close SaveChanges:=False
End With

'Delete the file you have send
Kill TempFilePath & TempFileName & FileExtStr

Set OutMail = Nothing
Set OutApp = Nothing

With Application
.ScreenUpdating = True
.EnableEvents = True
End With
End Sub

 

[Roncancio]

.BCC = Worksheets("Blad1").Range("A12").Value

Met vriendelijke groet,


Roncancio

 

[tonsie]

bedankt voor je reactie maar als ik dit invul blijft bcc leeg terwijl de cel op blad1 a12 gevuld is met een mailadres

 

[Roncancio]

bedankt voor je reactie maar als ik dit invul blijft bcc leeg terwijl de cel op blad1 a12 gevuld is met een mailadres

Heet het werkblad ook Blad1?
Anders zou je kunnen kiezen voor:

.BCC = Worksheets(1).Range("A12").Value

Met vriendelijke groet,


Roncancio

 

[tonsie]

Hoi Roncancio je hebt natuurlijk gelijk het moest blad 1 zijn en natuurlijk werkt het dan.
stom stom !! maar ik ben enorm geholpen bedankt voor je hulp.
groet Ton

 

[Roncancio]

Hoi Roncancio je hebt natuurlijk gelijk het moest blad 1 zijn en natuurlijk werkt het dan.
stom stom !! maar ik ben enorm geholpen bedankt voor je hulp.
groet Ton

Graag gedaan.
Graag nog even de vraag op opgelost zetten.
Bvd.

Met vriendelijke groet,


Roncancio