VBA - Geselecteerde maplocatie naar cel

[Tonex]

Hallo,

Met onderstaande VBA wordt een venster geopend waarmee een maplocatie geselecteerd kan worden.
Deze macro toegewezen aan een "knopje" in een excel-blad.
Ik zou graag de geselecteerde map in een cel willen weergeven, (bijv. Blad 1 cel A1).

Zou iemand mij willen helpen aub ...
(Regels in de code die er minder toe doen, wat naar rechts gezet).
Weinig kennis van VBA ter info !

[B]Sub Maplocatie()

Dim intResult As Integer
Dim strPath As String[/B]

                        'Start maplocatie wijzigen ipv standaard
                        Application.FileDialog(msoFileDialogFolderPicker).InitialFileName = "C:\"

                        'Vensternaam wijzigen ipv standaard
                        Application.FileDialog(msoFileDialogFolderPicker).Title = "Selecteer maplocatie"

                        'Buttonnaam wijzigen ipv standaard
                        Application.FileDialog(msoFileDialogFolderPicker).ButtonName = "Selecteer maplocatie"

                        'Venster FileDialogFolderPicker openen
intResult = Application.FileDialog(msoFileDialogFolderPicker).Show

                        'Controleer of het venster is gecancled
If intResult <> 0 Then

                        'Weergeven van message box
Call MsgBox(Application.FileDialog(msoFileDialogFolderPicker).SelectedItems(1), vbInformation, "Geselecteerde maplocatie")

End If

End Sub

 

[edmoor]

Je gebruikt 5x een nieuwe instantie van hetzelfde object zonder er iets mee te doen. 1x is voldoende. Bekijk deze eens:

Sub VraagMapnaam()
    With Application.FileDialog(msoFileDialogFolderPicker)
        .InitialFileName = "C:\"
        .Title = "Selecteer maplocatie"
        .ButtonName = .Title
        .Show
        If .SelectedItems.Count > 0 Then
            Sheets("Blad1").Range("A1") = .SelectedItems(1)
        End If
    End With
End Sub

 

[Tonex]

Werkt uitstekend edmoor !!

Bedankt voor de snelle en goede hulp :thumb: