Verborgen blad als pdf

[appie36]

Hallo,

In het voorbeeld een simpele weergave van mijn probleem, via dit forum heb ik het voor elkaar dat ik met een command button een pdf kan maken van een tabel die op een ander tabblad staat. Ik dacht ik kan dan mooi dat tabblad verbergen om alles er wat eenvoudiger uit te laten zien en te voorkomen dat anderen er in gaan rommelen. Als ik nu blad 2 verberg dan werkt die knop om een pdf te maken ook niet meer.
Is hier nog een oplossing voor of is dat niet mogelijk?

Mvg,
Ab

 

[edmoor]

Doe het eens zo:

Sub CommandButton1_Click()
    On Error GoTo errhandler
    With Sheets("Blad2")
        [COLOR="#FF0000"].Visible = True[/COLOR]
        .ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=.Range("D6") & " Meststoffen Planning", _
        OpenAfterPublish:=True
[COLOR="#FF0000"]        .Visible = False[/COLOR]
    End With
    Exit Sub
errhandler:
    MsgBox "Bestand kon niet worden opgeslagen, mogelijk is het vorige bestand nog geopend."
End Sub

 

[snb]

Na opschonen opname-VBA:

Sub CommandButton1_Click()
  With Sheets("Blad2")
    [COLOR=#FF0000].Visible = True[/COLOR]
    .ExportAsFixedFormat 0, .Range("D6")& " Meststoffen Planning"
[COLOR=#FF0000]    .Visible = False[/COLOR]
  End With
End Sub

 

[appie36]

Edmoor,

Bedankt voor de snelle reactie, het werkt. Die van snb is mooi kort maar ik kan niet terug vinden waar het bestand word opgeslagen en het bestand word ook niet geopend na het maken.

 

[edmoor]

Maak er dan dit van voor de duidelijkheid:

Sub CommandButton1_Click()
  With Sheets("Blad2")
    .Visible = True
    .ExportAsFixedFormat 0, ThisWorkbook.Path & "\" & .Range("D6")& " Meststoffen Planning", OpenAfterPublish:=True
    .Visible = False
  End With
End Sub

Dan wordt de PDF opgeslagen in de map waar je Excel document staat.

 

[appie36]

Oke, bedankt voor de snelle reactie.
Prima op deze manier.

 

[edmoor]

Nog iets aangepast om die PDF direct te openen.

 

[appie36]

Ah, ja ik zie het. Bedankt voor het mee denken

 

[snb]

Waarom zou je de PDF meteen willen openen ?

 

[appie36]

Collega's gaan mijn lijst gebruiken, kunnen ze meteen zelf zien wat er gebeurt en ergens opslaan waar ze het zelf willen.

 

[snb]

Je werkt als organisatie efficiënter als je voor iedereen dezelfde lokatie hanteert voor de opslag van dit soort documenten. Dat maakt opslaan en zoeken veel eenvoudiger en minder fout-gevoelig. Standaardisatie is de sleutel tot succes.

 

[edmoor]

Collega's gaan mijn lijst gebruiken, kunnen ze meteen zelf zien wat er gebeurt en ergens opslaan waar ze het zelf willen.

Kijk dan eens naar dit:

Sub CommandButton1_Click()
    Map = SelecteerMapnaam
  With Sheets("Blad2")
    .Visible = True
    .ExportAsFixedFormat 0, Map & "\" & .Range("D6") & " Meststoffen Planning", OpenAfterPublish:=True
    .Visible = False
  End With
End Sub

Function SelecteerMapnaam()
    With Application.FileDialog(msoFileDialogFolderPicker)
        .InitialFileName = "C:\"
        .Title = "Selecteer opslaglocatie"
        .ButtonName = .Title
        .Show
        If .SelectedItems.Count > 0 Then
            SelecteerMapnaam = .SelectedItems(1)
        End If
    End With
End Function

 

[snb]

@Ed

 If .Show Then SelecteerMapnaam = .SelectedItems(1)

geeft hetzelfde resultaat als:

 .Show
If .SelectedItems.Count > 0 Then
  SelecteerMapnaam = .SelectedItems(1)
End If

 

[edmoor]

Correct.
Uiteraard