Verticaal naar horizontaal

[BOUKES]

Kan ik met formules de data die nu onder elkaar staat horizontaal per nummer in het gele vak krijgen.
In het voorbeeld heb ik in het groene vak een paar nummers ingevuld, dan wordt het wel duidelijk.
Bedankt vast

 

[JEC.]

Gebruik je office 365?

In D1: =UNIEK(A1:A40)
In E1: =TRANSPONEREN(FILTER($B$1:$B$40;$A$1:$A$40=D1))

 

[JeanPaul28]

zonder 365

 

[JEC.]

Hier ook nog optie zonder office 365, die je als niet matrix kan doorvoeren

In D1: =INDEX($A$1:$A$40;AGGREGAAT(15;6;1/(1/((VERGELIJKEN($A$1:$A$40;$A$1:$A$40;0)=RIJ($1:$40))*RIJ($1:$40)));RIJ(A1)))
In E1: =ALS.FOUT(INDEX($B$1:$B$40;AGGREGAAT(15;6;1/(1/(($A$1:$A$40=$D1)*(RIJ($1:$40))));KOLOM(A1)));"")

 

[BOUKES]

Aanpassing

Het is een bestand voor mijn werk, daar gebruiken we office 2016 plus

Ik gebruik dus graag de index formule

2 vragen
Stel als ik nieuwe gegevens invoer in kolom A en B waarbij er iemand 4 taken heeft zoals 120 dan verschuift ie naar de 2e rij
Als ik een nummer verander zodat er 2x 1726 komt te staan dan verschuift deze ook.(ZIE BIJLAGE)

Is dit zo aan te passen dat er zelfs 6 taken kunnen staan
Er staat ook overal #GETAL! ??

 

[JEC.]

Ik heb de formule aangepast in de vorige post waardoor die fouten niet meer zichtbaar zijn, dmv ALS.FOUT
Je krijgt een nieuwe regel omdat de getallen in kolom A zijn opgemaakt als tekst (te zien aan het groene driehoekje in de cel).

Selecteer alle cellen en je ziet een oranje ruitje met een uitroepteken die je vraagt om te converteren naar getal. Doe dat eens en voeg daarna rijen toe.

 

[BOUKES]

Helemaal TOP
Morgen eens wat verder uitproberen.
VET bedankt !!!

 

[JEC.]

Deze geeft een unieke lijs terug, vermoedelijk als niet matrix in oudere versies(vanaf 2013), weet het echter niet zeker. Misschien dat iemand dat eens wil testen.

=INDEX(XML.FILTEREN("<x><y>"&TEKST.COMBINEREN("</y><y>";;$A$1:$A$41)&"</y></x>";"//y[not(.=preceding::y)]");RIJ(A1))