verticaal zoeken op laatste 4 cijfers

[ewh]

in het gele vak willen we de laatste 4 cijfers invullen
zodra het 4de cijfer er staat dan zal de filterfunctie moeten gaan werken zodat het betreffende , volledige nummer , zichtbaar is nadat kolom C is ingevuld
zal de filtering ongedaan worden gemaakt en het bestandje gesaved worden.

ben al weer even aan het stoeien ,maar lukt mij nog niet echt , wie kan helpen?

in de bijlage een bestandje toegevoegd

 

[AlexCEL]

Het gevraagde zit toch gewoon in de filterfunctie van Excel? (tekstfilters)

Waarom dan nabouwen (wordt VBA).

 

[ewh]

om het de gebruiker makkelijker te maken
en omdat ik het eigenlijk wel leuk vindt om het zo optelossen
maar kan je helpen?

 

[JEC.]

Achter je werkblad

Private Sub Worksheet_Change(ByVal Target As Range)
 If Target.Address(0, 0) = "B3" Then Range("A4:D12").AutoFilter 2, "*" & Target
 If Not Intersect(Target, Range("C5:C100")) Is Nothing And AutoFilterMode Then AutoFilterMode = False
End Sub

 

[AlexCEL]

Als niet-VBA expert wat gepuzzeld en ik kwam hier op uit:

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.Address = Range("B3").Address Then
    Range("A4:D100").AutoFilter Field:=2, Criteria1:="*" & Range("B3").Value
   End If
End Sub

 

[snb]

Verwijder de eerste 2 lege rijen.
Maak van de tabel een echte tabel (invoegen/tabel)

Private Sub Worksheet_Change(ByVal Target As Range)
  With ListObjects(1).DataBodyRange
    .AutoFilter
    If Target.Address = "$B$1" And Not .Columns(2).Find(Target, , , 2) Is Nothing Then .AutoFilter 2, "*" & Target
  End With
End Sub

 

[AD1957]

Met een Userform.

 

[ewh]

mannen, bedankt veel verschillende oplossingen ik ben begonnen met de oplossing van JVEER
en heb daar wat aan toegevoegd, maar het gaat niet zo als ik wil
de code heb ik achter het werkblad gezet in het bestandje wat ik heb bijgevoegd

de bedoeling uiteindelijk is als volgt

in het gele vak zet je de laatste 4 cijfers van het nummer in kolom B en selecteer deze ( dit lukt prima met de code)
in kolom C wordt nu een naam gezet en dan zal automatisch de datum van uitgifte ( vandaag ) gezet worden in kolom A ( dit lukt ook )
nu is de wens dat het gele vak B3 weer leeg gemaakt wordt en de sheet "in ruste is" voor de volgende opzoek sessie ( dit lukt nog niet )

als het nummer is gebruikt dan moeten we weer de juiste regel opzoeken en in kolom D zal dan een adres genoteerd worden waar het nummer is gebruikt en in kolom E de datum van afmelding ( dat lukt )
maar het gele vakje B3 wordt niet schoon gemaakt en het filter wordt niet opgeheven.
wie heeft er een idee? en kan nog even helpen?

 

[VenA]

Breng een beetje structuur aan in de code

Private Sub Worksheet_Change(ByVal Target As Range)
  If Not Intersect(Target, Range("B3,C5:D304")) Is Nothing Then
    Select Case Target.Column
      Case 2: Range("A4:E304").AutoFilter 2, "*" & Target.Value
      Case 3
        Target.Offset(, -2) = IIf(Target.Value = "", "", Date)
        Range("b3") = ""
      Case 4
        Target.Offset(, 1) = IIf(Target.Value = "", "", Date)
        Range("b3") = ""
    End Select
  End If
End Sub

 

[AD1957]

Zo?

Private Sub Worksheet_Change(ByVal Target As Range)
 If Target.Address(0, 0) = "B3" Then Range("A4:E304").AutoFilter 2, "*" & Target

 If Not Intersect(Target, Range("C5:D304")) Is Nothing And AutoFilterMode Then
    [B3] = ""
    AutoFilterMode = False
 End If
On Error GoTo einde
    If Target.Column = 3 Then
        If Target.Value <> "" Then Target.Offset(0, -2).Value = Date
    End If
    
    If Target.Column = 4 Then
        If Target.Value <> "" Then Target.Offset(0, 1).Value = Date
    End If
   
einde:

End Sub

Bijna zeker loop je nog tegen problemen aan.

 

[ewh]

geweldig, bedankt we zijn weer wat wijzer geworden .