Voorwaardelijke opmaak

[elda]

Als men in excel een voorwaardelijke opmaak uitvoert heeft men slechts 3 mogelijkheden.
Is er een weg dat men een 4de en 5de voorwaardelijke opmaak kan laten uitvoeren?
Ik wil in bepaalde velden, na het inbrengen van bijvoorbeeld "v" een groene kleur hebben in die bepaalde cel en bijvoorbeeld "r" een gele kleur.
Is daar een uitweg voor?

Jaak

 

[Wigi]

Enkel met VBA.

Of Excel 2007 gebruiken.

 

[elda]

als ik naar vba ga, benik dan de vorige voorwaardelijke opmaken kwijt, of blijf ik die behouden?
en
hoe moet ik dit dan definiëren?
klopt mijn volgende redenering:
sub color3()
set c=activesheet.range("d4")
for i=1 to 19
if c.offset(i,0).value="v"then
c.offset(i,0).interior.colorindex=range("b16").interior.colorindex
elself c,offset(i,0).value="r" then
c.offset(i,0).interior.colorindex=range("c16").interior.colorindex
else
c.offset(i,0).interior.colorindex=xInone
end if
next
end sub

 

[Demeter]

Plaats eens een voorbeeld file waarin er wordt aangeduid welke cellen er welke kleuren moeten krijgen bij welke voorwaarde?

ps.
Kan je de volgende keer de code tags gebruiken als je code plaatst? Dat is een stuk overzichtelijker. Bedankt.

 

[robdgr]

Een oud-collega van me heeft onderstaande code ooit hier gekregen. Daarom is het feitelijk een herhaling van eerdere informatie:

Sub Inkleuren() 

 Application.ScreenUpdating = False 
'Eventueel de bladbeveliging uitschakelen om kleuren toe te voegen 
      '  ActiveSheet.Unprotect Password:="?" 
'Hieronder de gewenste range invullen 
        Range("C10:GC81").Select 
For Each cell_in_loop In Selection 
'Bij ? de waarde invullen waarnaar gezocht moet worden 
    If cell_in_loop.Value = ("Z") Then 
        With cell_in_loop.Interior 
        'De kleur kiezen die gewenst is 
        .ColorIndex = 38 
        End With 
    End If 
Next 
For Each cell_in_loop In Selection 
'Bij ? de waarde invullen waarnaar gezocht moet worden 
    If cell_in_loop.Value = ("B") Then 
        With cell_in_loop.Interior 
        'De kleur kiezen die gewenst is 
        .ColorIndex = 40 
        End With 
    End If 
Next 
For Each cell_in_loop In Selection 
'Bij ? de waarde invullen waarnaar gezocht moet worden 
    If cell_in_loop.Value = ("RI") Then 
        With cell_in_loop.Interior 
        'De kleur kiezen die gewenst is 
        .ColorIndex = 36 
        End With 
    End If 
Next 
For Each cell_in_loop In Selection 
'Bij ? de waarde invullen waarnaar gezocht moet worden 
    If cell_in_loop.Value = ("RV") Then 
        With cell_in_loop.Interior 
        'De kleur kiezen die gewenst is 
        .ColorIndex = 37 
        End With 
    End If 
Next 
For Each cell_in_loop In Selection 
'Bij ? de waarde invullen waarnaar gezocht moet worden 
    If cell_in_loop.Value = ("J") Then 
        With cell_in_loop.Interior 
        'De kleur kiezen die gewenst is 
        .ColorIndex = 6 
        End With 
    End If 
Next 
For Each cell_in_loop In Selection 
'Bij ? de waarde invullen waarnaar gezocht moet worden 
    If cell_in_loop.Value = ("TL") Then 
        With cell_in_loop.Interior 
        'De kleur kiezen die gewenst is 
        .ColorIndex = 35 
        End With 
    End If 
Next 
For Each cell_in_loop In Selection 
'Bij ? de waarde invullen waarnaar gezocht moet worden 
    If cell_in_loop.Value = ("TR") Then 
        With cell_in_loop.Interior 
        'De kleur kiezen die gewenst is 
        .ColorIndex = 39 
        End With 
    End If 
Next 
For Each cell_in_loop In Selection 
'Bij ? de waarde invullen waarnaar gezocht moet worden 
    If cell_in_loop.Value = ("V") Then 
        With cell_in_loop.Interior 
        'De kleur kiezen die gewenst is 
        .ColorIndex = 3 
        End With 
    End If 
Next 
For Each cell_in_loop In Selection 
'Bij ? de waarde invullen waarnaar gezocht moet worden 
    If cell_in_loop.Value = ("C") Then 
        With cell_in_loop.Interior 
        'De kleur kiezen die gewenst is 
        .ColorIndex = 34 
        End With 
    End If 
Next 
'De For .... Next herhalen tot alle kleuren zijn gebruikt, in jouw geval 8 

End Sub

Informatie over kleurnummer vind je hier

Succes,

 

[Wigi]

Rob

9 keer door al die cellen loopen is niet nodig, 1 keertje is al genoeg hoor...

 

[Wigi]

Sub Inkleuren()
    Application.ScreenUpdating = False
    'Eventueel de bladbeveliging uitschakelen om kleuren toe te voegen: ActiveSheet.Unprotect Password:="?"

    Dim cell_in_loop As Range
    For Each cell_in_loop In Range("C10:GC81")
        With cell_in_loop
            Select Case .Value
                Case "Z": .Interior.ColorIndex = 38
                Case "B": .Interior.ColorIndex = 40
                Case "RI": .Interior.ColorIndex = 36
                Case "RV": .Interior.ColorIndex = 37
                Case "J": .Interior.ColorIndex = 6
                Case "TL": .Interior.ColorIndex = 35
                Case "TR": .Interior.ColorIndex = 39
                Case "V": .Interior.ColorIndex = 3
                Case "C": .Interior.ColorIndex = 34
            End Select
        End With
    Next
    Application.ScreenUpdating = True
End Sub

Wigi

 

[Demeter]

Netjes,
Maar is dit het antwoord op:

c.offset(i,0).interior.colorindex = range("b16").interior.colorindex

?
Er wordt namelijk verwezen naar een achtergrondkleur van een andere cel.
(ik kom hier zelf ook niet uit).

Kan ook dat de vraagstelling geheel fout is......... ben benieuwt!

 

[Wigi]

Jaak

de redenering klopt, en je verliest NIET de 3 eerdere voorwaardelijke opmaken.

 

[robdgr]

Volgens mij is dit het antwoord op:

Ik wil in bepaalde velden, na het inbrengen van bijvoorbeeld "v" een groene kleur hebben in die bepaalde cel en bijvoorbeeld "r" een gele kleur.

Ik lees hier dus dat de cel moet verkleuren na het inbrengen van een bepaalde letter.

 

[Wigi]

Jaak,

is de vraag opgelost? Zo ja, duid dat dan even aan aub. Zo nee, leg uit wat er nog niet goed is.