Waarschuwing met verjaardag

[kaan]

Beste tijdens het zoeken vond ik een 2 oude maar helaas werkt het niet meer.
Bij google heb ik uren zitten zoeken naar een alternatief maar het wil mij niet lukken.

Zou een van de Ecxel profs deze code kunnen aanpassen?

Mijn dank is groot

Kaan

Allereerst een label aanmaken in Excel (beeld, werkbalk, Werkset besturingselementen aanvinken. Uit de werkblak kiezen voor Tekstvak. Tekstvak naar je zin vormgeven. Boven het tekstvak een opdrachtknop zetten. Deze gebruik je om het tekstvak weg te klikken.

De onderstaande code plakken in de editor van ThisWorkbook (Alt & F11):

Private Sub Workbook_Open()
Tekst = "": n = 0
For i = 11 To 9999
If Month(Cells(i, 4)) * 100 + Day(Cells(i, 4)) = Month(Date) * 100 + Day(Date) Then Tekst = Tekst & Cells(i, 3) & Chr(10): n = n + 1
Next i
Worksheets(1).TextBox1.Text = Tekst
TextBox1.Height = n * 15
TextBox1.Visible = True
CommandButton1.Visible = True
Range("A2").Select
End Sub

In de editor van het werkblad:
Private Sub CommandButton1_Click()
TextBox1.Visible = False
CommandButton1.Visible = False
End Sub

 

[Wigi]

Ik begrijp bovenstaande code, maar wat is nu eigenlijk jouw bedoeling? Wat moet er in de MsgBox komen? Hoeveel dagen op voorhand?

 

[kaan]

Ik begrijp bovenstaande code, maar wat is nu eigenlijk jouw bedoeling? Wat moet er in de MsgBox komen? Hoeveel dagen op voorhand?

WIGI,

Kun je even kijken naar de bijlage? ik heb het daar proberen uit te leggen.


Mijn dank is groot.

 

[Wigi]

Voilà

Private Sub Workbook_Open()
    Dim Tekst As String, n As Long, c As Range, VerjDitJaar As Date

    Tekst = ""
    n = 0
    For Each c In Range("C2:C" & Range("C" & Rows.Count).End(xlUp).Row).SpecialCells(xlCellTypeConstants)
        VerjDitJaar = DateSerial(Year(Date), Month(c), Day(c))
        If VerjDitJaar <= Date + 7 And VerjDitJaar >= Date Then
            Tekst = Tekst & Chr(10) & c.Offset(, -1) & " is op " & VerjDitJaar & " jarig"
            n = n + 1
        End If
    Next
    MsgBox Tekst, vbInformation + vbOKOnly, "Verjaardagskalender"
    Sheets(1).TextBox1.Text = Tekst
    TextBox1.Height = n * 15
    TextBox1.Visible = True
    CommandButton1.Visible = True
    Range("C2").Select
End Sub

Wigi

 

[kaan]

WIGI,

Ik krijg de volgende fout melding zie foto Alstublieft.

Fout 13 tjdens uitvoering:

Typen komen niet met elkaar overeen

VerjDitJaar = DateSerial(Year(Date), Month(c), Day(c))

Wat zal mijn foet zijn?

 

[Wigi]

Staat er nog andere tekst in kolom C (behalve dat op rij 1)?

 

[kaan]

Ja dat was hem, ik hem hem nu aangepast en popup werkt wel maar krijg nu weer een andere fout melding. zie bijlage alstublieft

 

[Wigi]

Dit werkt wel.

Private Sub Workbook_Open()
    Dim Tekst As String, n As Long, c As Range, VerjDitJaar As Date

    Tekst = ""
    n = 0
    For Each c In Range("D4:D" & Range("D" & Rows.Count).End(xlUp).Row)
        VerjDitJaar = DateSerial(Year(Date), Month(c), Day(c))
        If VerjDitJaar <= Date + 7 And VerjDitJaar >= Date Then
            Tekst = Tekst & Chr(10) & c.Offset(, -1) & " is op " & VerjDitJaar & " jarig"
            n = n + 1
        End If
    Next
    MsgBox Tekst, vbInformation + vbOKOnly, "Verjaardagskalender"
    With Sheets(1).TextBox1
        .Text = Tekst
        .Height = n * 15
        .Visible = True
    End With
    Sheets(1).CommandButton1.Visible = True
    Range("D4").Select
End Sub

Wigi

 

[kaan]

Hij doet het top.

Wigi, kun je er voor zorgen er geen popup is als er geen jarige is?

En hoe kan ik Kolom C erbij voegen in de popup dit voor de naam?

Als je daar ook even naar kan kijken zal het super zijn?

Mijn dank is groot.

 

[Wigi]

Wigi, kun je er voor zorgen er geen popup is als er geen jarige is?

Private Sub Workbook_Open()
    Dim Tekst As String, n As Long, c As Range, VerjDitJaar As Date

    Tekst = ""
    n = 0
    For Each c In Range("D4:D" & Range("D" & Rows.Count).End(xlUp).Row)
        VerjDitJaar = DateSerial(Year(Date), Month(c), Day(c))
        If VerjDitJaar <= Date + 7 And VerjDitJaar >= Date Then
            Tekst = Tekst & Chr(10) & c.Offset(, -1) & " is op " & VerjDitJaar & " jarig"
            n = n + 1
        End If
    Next
    If n > 0 Then MsgBox Tekst, vbInformation + vbOKOnly, "Verjaardagskalender"
    With Sheets(1).TextBox1
        .Text = Tekst
        .Height = n * 15
        .Visible = True
    End With
    Sheets(1).CommandButton1.Visible = True
    Range("D4").Select
End Sub

En hoe kan ik Kolom C erbij voegen in de popup dit voor de naam?

De naam staat toch al in de popup?

 

[kaan]

Nee, ik kan hem niet zien zie de bijlage alstublieft?


.

 

[Wigi]

Volgens de code moet de naam wel in de kolom links van de datums-kolom staan. Zoniet, code aanpassen!

 

[kaan]

Wim,

Dit gaat werken, ik ga hem nu aanpassen, mijn dank aan jou is groot.

Ik ben wel goed in Photoshop html PHP weet veel over website's mog je iets nodig hebben met jou site sta ik klaar tot jou dienst.

http://www.wimgielis.be/ :thumb:

Veel dank.

 

[Wigi]

PHP lijkt me iets te ver voorbij het doel van de site. Misschien later.

Maar als je de HTML wat wil uitvlooien, dan kan ik gerust eens een typisch HTMLbestandje van mijn site doorsturen, + het CSS bestandje. Layout trouwens zelf geleend van elders.

Wigi

 

[kaan]

Ik heb net mijn mail adres naar je hotmail toe gestuurd.

Gr, Kaan

 

[Wigi]

Ik heb ondertussen geantwoord ;-)