Weeknummers

[DesireeH]

Hi,

In mijn document moet excel automatisch de weeknummers berekenen. Hij maakt de berekening niet goed:

NF9 = 4-01-2016
Formule voor weeknummer =WEEKNUM(NF9;2)

Als uitkomst geeft excel aan dat 4-01-2016 een maandag in week 2 is, dit klopt niet. 4-01-2016 is week 1. Hoe krijg ik dit goed?

Alvast bedankt.

 

[edmoor]

Maak er eens dit van:
=ISO.WEEKNUMMER(NF9)

 

[DesireeH]

Ik krijg die formule er niet in Engels in...

 

[jkpieterse]

De iso weeknummer functie was toegevoegd in Excel 2013. Als jij een oudere versie hebt, dan kan het met een wat ingewikkeldere formule:

=INTEGER((A2-(DATUM(JAAR(A2+(REST(8-WEEKDAG(A2);7)-3));1;1))-3+REST(WEEKDAG(DATUM(JAAR(A2+(REST(8-WEEKDAG(A2);7)-3));1;1))+1;7))/7)+1

of in Engels:

=INT((A2-(DATE(YEAR(A2+(MOD(8-WEEKDAY(A2);7)-3));1;1))-3+MOD(WEEKDAY(DATE(YEAR(A2+(MOD(8-WEEKDAY(A2);7)-3));1;1))+1;7))/7)+1

Er zijn meer van dergelijke formules, deze kon ik snel opduiken...

 

[E v R]

dan ISOWEEKNUM(NF9) (in EXCEL2013)

 

[DesireeH]

Ik werk inderdaad in versie 2010. Maar het is gelukt met de lange formule. Bedankt!

 

[VenA]

In Xl-2010 = WEEKNUM(A1;21)

 

[jkpieterse]

WEEKNUM gebruikt de Amerikaanse weeknummering, die is anders dan de ISO weeknummering die wij in NL gebruiken.

 

[VenA]

Bij weeknum heb je in XL-2010 verschillende opties. De door de TS gebruikte 2 'week start op maandag systeem 1' hiervoor kan je ook 11 gebruiken. 21 'de week start op maandag systeem 2'. Deze geeft voor zover ik weet het ISO-weeknummer.

 

[snb]

@VenA

Dat klopt helemaal.
In Excel 2010 is het dus eenvoudiger dan in Excel 2013 =weeknummer(vandaag();21)

en als formule in 2007 en eerder:

=GEHEEL((A1-WEEKDAG(A1;2)+11-DATUM(JAAR(A1-WEEKDAG(A1;2)+4);1;1))/7)

en voor een toelichting op het een en ander:

http://www.snb-vba.eu/VBA_ISO_weeknummer.html

 

[prutsmonteur]

maar nu andersom

Ik probeer juist van weeknr. naar datum te gaan maar krijg het niet voor elkaar.
De bedoeling is doormiddel van jaartal in aparta cel, en weeknr. in aparte cel in te vullen, datums te genereren in weekdagen ma-za
Ik heb een wat oudere versie excel 2002.
Kan en wil iemand mij hiermee helpen.

Vriendelijke groet, Joop

Sorry vena, heb bericht aangepast en opnieuw als eigen bericht geplaatst.

 

[VenA]

Maak even een eigen vraag aan ipv in iemands anders draadje een vraag te stellen. Zet er gelijk een voorbeeldje bij.