x.zoeken zoeken matrix gegeven staan in meerdere kolommen.

[mbolder]

Ik wil graag de datum van een groep weergeven in een veld in tabblad 1.
De deelnemers staan in een ander blad (blad 2). Kolom A is de datum van de groep in de kolommen B tm N staan de deelnemers.
Er zijn meerdere groepen 13 dus 13 regels waarbij kolom A de datum van de groep is en in de kolommen B tm N staan de nrs. van de deelnemers.
In tabblad 1. staan de nrs. van de deelnemers en ik wil dus de bijbehorende datum weergeven.
Met X.ZOEKEN kan bij de 'zoeken matrix' volgens mij maar uit 1 kolom bestaan. Ik moet dus zoeken in kolom B tm N en in regel 1 tm 13.

Alvast bedankt voor je reactie!

 

[peter59]

Hallo,

Welkom op dit forum.
Je wordt sneller en beter geholpen als je een voorbeeldje upload met natuurlijk fake gegevens.
Geef tevens even aan welke Excel versie je gebruikt.

 

[AlexCEL]

@peter, als het een X.ZOEKEN vraag betreft --> Excel 365.

Verder inderdaad graag een Excel voorbeeldje plaatsen.

 

[peter59]

@AlexCEL

Je hebt volkomen gelijk. Mijn fout.

 

[AlexCEL]

Geen fout... gewoon een observatie.

 

[HSV]

Er is helaas geen blad2.

=ALS.FOUT(INDEX(Blad2!$A$2:$A$14;AGGREGAAT(15;6;RIJ($1:$13)/(Blad2!$B$2:$D$14=A1);1));"")

 

[mbolder]

Nieuw bestand geupload

Hallo Harry,
Dank voor je snelle reactie!.
Helaas geeft Excel aan dat ik teveel argumenten heb opgegeven voor deze functie.
Ik heb een nieuwe versie van het bestand ge-upload, inclusief blad 1.
Hopelijk wil je er nog een keer naar kijken.
Groeten Maria.

 

[AlexCEL]

Mag ik er ook naar kijken?

Probeer deze eens:

=SOMPRODUCT((Blad2!$B$2:$N$23=$A2)*(Blad2!$A$2:$A$23))

 

[mbolder]

Top deze formule werkt. Kan deze nog worden aangepast dat waarde 0 wordt weergegeven indien een cliëntnummer niet in de lijst staat?
=SOMPRODUCT((Blad2!$B$2:$N$23=$A2)*(Blad2!$A$2:$A$23))

 

[AlexCEL]

Deze is beter/mooier... voor Excel 365:

=FILTER(Blad2!A$2:A$23;BYROW(Blad2!B$2:N$23;LAMBDA(x;SOM(--(x=A2))));"niet gevonden")

 

[mbolder]

Dank, deze Filter begrijp ik ook beter.

 

[HSV]

De formule gaf inderdaad een fout aan, maar dat komt omdat je het niet goed hebt overgenomen.

De index van het verkeerde blad genomen, er miste een haakje sluiten en een 1 en je moest enkel het juiste bereik invullen.

=ALS.FOUT(INDEX(Blad1!$A$2:$A$14;AGGREGAAT(15;6;RIJ($1:$13/(Blad2!$B$2:$D$14=A1);));"")

=ALS.FOUT(INDEX([COLOR=#ff0000]Blad2![/COLOR]$A$2:$A$[COLOR=#ff0000]23[/COLOR];AGGREGAAT(15;6;RIJ($1:$[COLOR=#ff0000]22[SIZE=4])[/SIZE][/COLOR]/(Blad2!$B$2:$[COLOR=#ff0000]N$23[/COLOR]=A[COLOR=#ff0000]2[/COLOR]);[COLOR=#ff0000]1[/COLOR]));"")

 

[peter59]

Of misschien d.m.v. power query?
De functies van AlexCEL en HSV heb ik hier ook in mee genomen.

 

[JEC.]

Nog eentje zonder lambda

=LET(r;Blad2!A$2:N$23;x;MMULT(N(r=A3);SEQUENCE(COLUMNS(r);;1;0));FILTER(INDEX(r;;1);x;"niet gevonden"))

 

[HSV]

Evenals.

=ALS.FOUT(LET(x;Blad2!A$2:N$23;y;NAAR.KOLOM(ALS(x=A2;INDEX(x;;1);""));FILTER(y;y<>""));"niet gevonden")

Dynamisch, maar helaas niet op volgorde.

=FILTER(LET(x;Blad2!A2:A23;INDEX(x;REEKS(RIJEN(x)*13;;;1/13);1));AANTAL.ALS(A2:A10;NAAR.KOLOM(Blad2!B2:N23)))

 

[JEC.]

Deze is op volgorde

=DROP(REDUCE("";A3:A11;LAMBDA(a;b;VSTACK(a;LET(r;Blad2!A2:N23;x;MMULT(N(r=b);SEQUENCE(COLUMNS(r);;1;0));TAKE(FILTER(INDEX(r;;1);x;"niet gevonden");1)))));1)

 

[HSV]

Geeft onderaan 5 extra data die er niet horen.
Zo niet.

=WEGLATEN(REDUCE("";[COLOR=#ff0000]NAAR.KOLOM(A2:A10;1)[/COLOR];LAMBDA(a;b;VERT.STAPELEN(a;LET(r;Blad2!A2:N23;x;PRODUCTMAT(N(r=b);REEKS(KOLOMMEN(r);;1;0));NEMEN(FILTER(INDEX(r;;1);x;"niet gevonden");1)))));1)

 

[JEC.]

Bij mij laat hij die extra data niet zien (bestand peter)

 

[JEC.]

Nog eentje dan

=LET(r;Tabel1;d;INDEX(TAKE(r;;1);SEQUENCE(ROWS(r)*13;;;1/13));c;TOCOL(DROP(r;;1));XLOOKUP(A3:A11;c;d;"niet gevonden"))

 

[HSV]

Precies @JEC,
Zo had ik het ook eerst staan, maar ik krijg hem niet aan de praat.
Vandaar mijn andere bijdrage.

Kijk maar eens in het bestand naar cel M2.
De formule wijkt op zich niet af van die van jou, enkel geen tabel gebruik.
In losse delen werkt het prima (kolommen B, C, en in E het resultaat).