Zoeken in een deel tekst

[Kevinw01]

Goedenmiddag,

Ik heb een vraag met betrekking tot het zoeken in een bepaald deel van een tekst. Ik heb mijn eigen al verloren gezocht of hier iets voor is.

In het bijgevoegde excel zie je in kolom A de juiste straatnamen staan.
In kolom B zie je adres gegevens staan met daarin midden in de tekst ook een straatnaam.

Nu wil ik een match maken en kijken of de straatnaam van kolom A overeenkomt met die van kolom B en hiervan een resultaat weer te geven in kolom C (bijvoorbeeld: straatnaam oke, straatnaam niet oke)

is hier een formule voor die ik in C1 kan invullen en doortrekken naar beneden. Want he gaat hier om 15000 items. Ik heb zelf al geprobeerd met vert.zoeken, vind.spec, index, etc. maar helaas kreeg ik geen resultaten. Misschien zie ik iets over het hoofd? Graag jullie hulp. Alvast bedankt.

Mvg,

Kevin

Bekijk bijlage Voorbeeld.xlsx

 

[AlexCEL]

Probeer deze eens in C1 en verder:

=ALS.FOUT(VERT.ZOEKEN("*"&A1&"*";$B$1:$B$25000;1;ONWAAR);"straat niet gevonden")

 

[Kevinw01]

Beste Alex,

Ik krijg helaas nog niet de juiste output.
Ik krijg met de formule straatnamen die niet overeenkomen met kolom B.

Toch alvast bedankt. :d

 

[AlexCEL]

Kun je dan even een toelichting geven? Wat moet er in C1 komen te staan? Welke uitkomst verwacht je daar? En in C2?

Of moet Excel kijken of de straat genoemd in B1 ERGENS in kolom A voorkomt?

 

[Kevinw01]

Bekijk bijlage Voorbeeld.xlsx

Als je in het bijgevoegde bestand kijkt zie je dat ik jouw formule heb toegevoegd. In Cel c 23 staat Kauterstraat, terwijl in cel B23 Linde staat. Dus deze zijn niet gelijk.

In Cel A42 zie je Wilheminastraat staan, deze zou dan in cel C3 moeten komen staan, omdat in cel B3 ook Wilhelminastraat staat.

Ik hoop hiermee mijn probleem duidelijker heb geschetst.

 

[AlexCEL]

Dus mijn laatste opmerking klopt: je wilt dat Excel kijkt of de straat genoemd in B1 ERGENS in kolom A voorkomt.

Probeer deze matrixformule eens (invoeren in C1 en afsluiten met control+shift+enter):

=ALS(SOM(ALS.FOUT(VIND.SPEC($A$1:$A$86;B1);0))=0;"Straatnaam niet oke";"Straatnaam oke")

Als je lijst langer is moet i.p.v. A86 de laatste cel van je bereik ingevuld worden (bijv. A15001 of zo). Als je dit ook wilt automatiseren dan kan het bijvoorbeeld zo:

=ALS(SOM(ALS.FOUT(VIND.SPEC(INDIRECT("$A$1:$A$"&AANTALARG($A$1:$A$25000));B1);0))=0;"Straatnaam niet oke";"Straatnaam oke")

Hier wordt automatisch de laatste rij opgezocht en de verwijzing aangepast.

 

[Kevinw01]

Hoi Alex,

Het lijkt erop dat de laatste formule werkt, mijn dank is hier groot voor
Is het misschien ook mogelijk om uit te leggen wat er precies gebeurd zodat ik deze de volgende keer misschien weer kan toepassen?

nogmaals bedankt!

Groeten

 

[AlexCEL]

Matrix-formule:

=ALS(SOM(ALS.FOUT(VIND.SPEC($A$1:$A$86;B1);0))=0;"Straatnaam niet oke";"Straatnaam oke")

Lees van binnen naar buiten:

VIND.SPEC($A$1:$A$86;B1) --> Zoek of straat uit kolom A voorkomt in B1, beginnend bij A1 en doorlopend tot A86 (matrix-formule). Als de straat gevonden wordt, wordt de plaats van de 1e letter weergegeven van de straat weergegeven. Het resultaat is een matrix met getallen (en/of foutmeldingen...)

ALS.FOUT(VIND.SPEC($A$1:$A$86;B1);0) --> Als de straat nergens gevonden wordt is het resultaat #N/B, oftewel een foutmelding. ALS.FOUT zegt excel wat er dan moet gebeuren, in dit geval de waarde 0 retourneren.

SOM(ALS.FOUT(VIND.SPEC($A$1:$A$86;B1);0)) --> Hier wordt de som van de matrix bepaald.

ALS(SOM(...))=0 --> als de som 0 is dan is de straat nergens gevonden en moet de waarde "Straatnaam niet oke" weergegeven worden.

Matrixformule wil zeggen dat excel in plaats van de waarde uit een enkele cel, de waardes uit een reeks cellen gaat invullen. Dat gebeurt hier dus ook.

 

[Kevinw01]

Helder Alex!, dank je wel voor je input en informatie! :d