Zoeken met exacte waarde weergeven

[Druifje236]

Bekijk bijlage Probleem Druifje236.xlsx

In bijgaand voorbeeld heb ik een aantal data die ik graag weergegeven wil hebben op het moment dat het die datum ook is. Echter, als de datum is geweest, dan blijft hij de kop weergeven. Terwijl dit dus niet juist is.

Voorbeeld: Afgelopen zondag is het nog 3 weken tot aan de datum voor Djoanie, maar in de "Bijzonderheden" kolom blijft hij 3 weken aangeven, totdat het veranderd naar 2 weken.

Zo ook bij Bertina, Marie en Rowena. En op a.s. zaterdag zal dat ook voor Ingrid het geval zijn.

Wat ik dus eigenlijk wil, is dat alleen als het daadwerkelijk 3 weken is (dus op de dag af) dat die cel wordt gevuld en tussen 3 en 2 weken dus geen cel gevuld is. Hetzelfde geldt voor tussen 2 weken en 10 dagen. Daarna gaat het allemaal zijn gangetje...

De formule die ik nu gebruik is: =ALS.FOUT(ZOEKEN(VANDAAG();I2:U2;$I$1:$U$1);"")
Verticaal of Horizontaal zoeken geeft helemaal niet de info die ik wil.

Wat mis ik?

 

[VenA]

Gaat de vraag over zoeken of om het resultaat? Waarom is de tabel geen tabel meer?

Je kan het aantal dagen en/of weken toch vrij eenvoudig berekenen.

=IF([@Datum]-TODAY()<11;[@Datum]-TODAY()&" dagen";INT(([@Datum]-TODAY())/7)&" weken")

De formule is vrij eenvoudig uit te bereiden om er wat schoonheidsfoutjes uit te halen.

Nb. Het ISO-weeknummer kan je vanaf XL-2010 ook opvragen met =Weeknum(datum;21)

 

[Druifje236]

Gaat de vraag over zoeken of om het resultaat? Waarom is de tabel geen tabel meer?

Ik heb dit uit het originele document gekopieerd.

 

[Druifje236]

Gaat de vraag over zoeken of om het resultaat? Waarom is de tabel geen tabel meer?

Je kan het aantal dagen en/of weken toch vrij eenvoudig berekenen.

=IF([@Datum]-TODAY()<11;[@Datum]-TODAY()&" dagen";INT(([@Datum]-TODAY())/7)&" weken")

De formule is vrij eenvoudig uit te bereiden om er wat schoonheidsfoutjes uit te halen.

Nb. Het ISO-weeknummer kan je vanaf XL-2010 ook opvragen met =Weeknum(datum;21)

Ik heb een NL versie... Dus zou graag de formule die je hierboven hebt geschreven graag in het NL zien. Om te begrijpen wat je vraagt...

Het gaat om het resultaat, btw...
Ik vraag om de kop weer te geven, als in de rij de datum van vandaag voorkomt. Alleen zodra deze geweest is (bijv. gisteren), dan blijft hij de kop weergeven.

Ik heb deze gegevens nodig in een ander tablad, waar dit resultaat weer een reactie moet leveren op een andere formule, maar omdat ik dus meerdere resultaten hetzelfde blijf houden in "Bijzonderheden" loopt de rest in het honderd.

 

[VenA]

En al het andere wat er staat negeer je maar? svp niet quoten en berichten kan je aanpassen. Het bestandje ook bekeken daar staan de formules zeer waarschijnlijk in het Nederlands.

 

[Druifje236]

Hiermee is mijn probleem niet opgelost, want hiermee heb ik 2 personen op 3 weken, 4 personen op 2 weken, 1 persoon op 1 weken staan en dan schakelt ie ineens naar 10 dagen (terwijl deze datum eerder valt)

Ik zal uitleggen waarvoor ik het nodig heb: Op de precieze datum moet ik deze dames een bericht sturen. Deze dames krijgen dus 3 weken voor de uiteindelijke datum een bericht. Daarna met 2 weken, dan met 10 dagen, 9 dagen, 8 dagen, 7 dagen, etc...

Het is dus van belang dat ik precies weet wanneer ik ze wel en geen bericht moet sturen.
Vandaar dat ik dus wil dat de cel weer leeg wordt, als de 3 weken deadline is geweest en de 2 weken deadline nog moet komen.

 

[MarcelBeug]

ZOEKEN zoekt met niet-exacte waarden. Als je toch ZOEKEN wilt gebruiken, moet je tweemaal zoeken: eenmaal om te kijken of de gezochte waarde voorkomt en zo ja dan nogmaals om de tekst uit het kopje te halen. Je hebt ook nog ALS.FOUT nodig voor het geval de gezochte waarde kleiner is dan de kleinste waarde in de zoeklijst.
In H2 en gekopieerd naar beneden:

=ALS(ALS.FOUT(ZOEKEN(VANDAAG();I2:U2)=VANDAAG();0);ZOEKEN(VANDAAG();I2:U2;$I$1:$U$1);"")

Dit lijkt misschien vreemd, maar het schijnt bij heel veel waarden toch sneller te zijn dan het alternatief met INDEX/VERGELIJKEN, in H2 en gekopieerd naar beneden:

=ALS.FOUT(INDEX($I$1:$U$1;VERGELIJKEN(VANDAAG();I2:U2;0));"")

Aangezien het hier weinig gegevens betreft, zou ik voor het INDEX/VERGELIJKEN alternatief gaan.

 

[VenA]

Volgens mij geeft dit hetzelfde resultaat zonder extra kolommen

=IF([@Datum]-TODAY()<11;[@Datum]-TODAY()&" dagen";IF(MOD(([@Datum]-TODAY());7)<>0;"";INT(([@Datum]-TODAY())/7)&" weken"))

 

[MarcelBeug]

Ja, dat is eigenlijk wel zo handig.

Een paar opmerkingen:
Deze "slaat ook aan" bij precies 4, 5 etc. weken.
De "<>0" kun je weglaten, want elk getal ongelijk nul is equivalent met true (of WAAR).
De INT is niet nodig. In dat stukje formule kom je sowieso al op een geheel getal uit.

Een en ander aangepast en in het nederlands:

=ALS([@Datum]-VANDAAG()<11;[@Datum]-VANDAAG()&" dagen";ALS(REST(MIN(22;([@Datum]-VANDAAG()));7);"";([@Datum]-VANDAAG())/7&" weken"))

Edit: deze formule kan ook output opleveren bij datums in het verleden

 

[VenA]

@MarcelBeug,

Terechte opmerkingen. Het gevolg van deel formules in één formule proppen. (Zal jou niet onbekend zijn).
En dat bijna alles beter/korter kan daar leren we, in dit geval ik, weer wat van.:d

 

[Druifje236]

Dank je wel! Nu klopt het helemaal! Ik heb me hier zeker 2 weken op los gegoogled en vierkante ogen opgestaard!

Topic opgelost!