Zoeken op basis van 3 criteria

[martijn78m]

Hallo,
Gelukkig lukt het mij om op basis van 2 criteria het juiste getal te vinden tijdens analyses, echter loop ik helaas tegen een beperking aan met deze formule, ik moet nu namelijk iets vinden op basis van een 3de criteria.

Er zijn 3 vervoerders, van alle 3 heb ik de kosten gekregen voor levering op basis van gewicht en het gebied waar de levering naar toe moet.
Nu wil ik echter in mijn simulatie het juiste getal vinden van vervoerder A, richting gebied 1 voor een pakket van 200kg.
In de lijst die ik hiervoor gebruik wil ik de uitkomsten horizontaal uitwerken, dus vervoerder A, B en C naast elkaar. Ik denk dat mijn formule met index zoeken was last heeft met het horizontaal matchen en verticaal matchen in 1 formule? Echter wil ik de layout wel graag zo houden omdat dit het meest overzichtelijk gaat werken.

Zie bijlage,

Hoe moet ik nu de formule opzetten voor dit extra criterium?

Alvast bedankt voor de hulp,:thumb:

 

[JEC.]

Probeer deze eens

=SOMPRODUCT(($F$13:$F$24=D$2)*($G$13:$G$24=$B3)*(($H$12:$T$12<=$C3)*(KOLOM(A1:M1))=VERGELIJKEN($C3;$H$12:$T$12;1))*($H$13:$T$24))

 

[martijn78m]

@JVeer, hartstikke bedankt, hij lijkt nu te kloppen inderdaad.
In eerste instantie kreeg ik bij vervoerder B en C een verkeerde uitkomst toen ik de formule doortrok, maar nadat ik formule Kolom(A1:M1)) had aangepast naar Kolom($A$1:$M$1)) toen klopte hij wel.

Ik vraag mij echter af waar deze kolom precies naar verwijst en wat zijn functie is, ik zie namelijk niet precies wat deze doet, daarnaast is de verwijzing A1:M1 ook niet een logische kolom verwijzing. Hoop dat je dit kunt toelichten zodat ik weet hoe ik deze formule het beste kan gaan toepassen in mijn analyse file.

=SOMP RODUCT(($F$13:$F$24=D$2)*($G$13:$G$24=$B3)*(($H$12:$T$12<=$C3)*(KOLOM(A1:M1))=VERGELIJKEN($C3;$H$12:$T$12;1))*($H$13:$T$24))

nogmaals dank!

 

[JEC.]

Dat zorgt ervoor dat er een kolomnummer wordt gekoppeld aan alles wat voldoet aan de voorwaarde.
Als er wordt voldaan aan een voorwaarde, geeft Excel Waar of Onwaar (1 of 0) terug. Een 1 vermenigvuldigd met een kolomnummer wordt dan omgezet naar het kolomnummer.

Met F9 kun je door de formule heen om te kijken hoe ieder deel werkt.

Ps: Er wordt bij kolom A begonnen omdat de telling dan vanaf 1 begint. Je zoekt in 13 kolommen dus in de kolom functie moeten ook 13 kolommen zitten.
(Kolom A tm M)

 

[AlexCEL]

Wat dachten jullie van deze?

=ALS.FOUT(INDEX($H$13:$U$241;VERGELIJKEN(D$2&$B3;$F$13:$F$24&$G$13:$G$24;0);VERGELIJKEN($C3;$H$12:$U$12;1));"?")

Mogelijk afsluiten met Control+Shift+Enter (matrixfunctie)

Of, iets exotischer, voor Excel 365:

=LET(x;FILTER($H$13:$U$24;$F$13:$F$24&$G$13:$G$24=D$2&$B3);ALS.FOUT(MAX(FILTER(x;$H$12:$U$12<=$C3));""))

 

[martijn78m]

@AlexCEL, bedankt en ziet er iets eenvoudiger en logischer uit, echter hij werkt niet in mijn voorbeeld template, zie bijlage. Ik krijg enkel het vraagteken. Hoop dat je mij kunt helpen om deze werkend te krijgen want qua formule is deze iets eenvoudiger dan de voorgaande.

@Jveer, bedankt voor de toelichting, en ik begrijp de verwijzing naar de 13 cellen. In mijn eigen analyse file werkt het goed! Erg bedankt voor je snelle support

 

[AlexCEL]

Uit mijn vorige post:

Mogelijk afsluiten met Control+Shift+Enter (matrixfunctie)

 

[martijn78m]

Uit mijn vorige post:

Sorry

Beide bedankt voor de hulp en de goede oplossing.