"ALS" formule in combinatie met "AFRONDEN" formule

[shalhevet]

Beste allemaal,

In mijn uren registratie bestand heb ik:

Kolom D - begin tijd

Kolom E - eind tijd

Kolom F - 0:30 (pauze)

Kolom G - formule =ALS((E21-D21)*24-0,5 > 0;(E21-D21)*24-0,5;"")

Als ik nu begin tijd 6:15 uur heb en eind tijd 17:20 met aftrek van 30 min pauze kom ik in kolom G op:

10,58333333

Nu wil ik de formule in kolom G aanpassen. Ik zou de huidige formule willen combineren met het "Afronden" formule.

Deze zou dan moeten kijken naar de dichtstbijzijnde getal. Dus bijv. 10:58 wordt 11 uur maar 10:09 wordt 10:15

Hoe kan ik dat aanpassen?

bij voorbaat dank

 

[HSV]

Je maakt een fout.

10,58 in getal, omgezet naar uren is niet bijna 11 uur, maar 10:35 uur.

=ALS(E21-D21-F21>0;AFRONDEN.N.VEELVOUD(E21-D21-F21;1/96);"")

Afronden op kwartier in tijd.
1/96 = 1 dag gedeeld door 24 gedeeld door 4 = 1 kwartier.

 

[Peter B]

Volgens mij moet dat zo werken. Vervang de formule in kolom G voor het volgende:

=ALS((E21-D21)*24-0,5 > 0;AFRONDEN((E21-D21)*24/0,25;0)*0,25/24;"")

En 0,25/24 = inderdaad 1/96 ... Kun je toch zien dat ik geen Giga Senior ben ...

 

[HSV]

En 0,25/24 = inderdaad 1/96 ... Kun je toch zien dat ik geen Giga Senior ben ...

Tja, we hebben een verschil van een half uur.
Zie bestandje.

 

[mcs51mc]

Vraag is natuurlijk waarop je wilt afronden ?
Dichtst bijzijnde uur, kwartier, half uur, 5 minuten ??
Wil je naar boven of naar onder afronden ???

In een UK Excel kan je dus de functies:

=ROUND(D3*24;0)/24
=ROUNDUP(D3*24;0)/24
=ROUNDDOWN(D3*24;0)/24

met 10:27 in cel D3 geven deze respectievelijk 10:00 ; 11:00 en 10:00 terug

Het getal 24 is voor afronden per uur.
Voor afronding per kwartier gebruik je 96
Voor afronding per half uur gebruik je 48
Voor afronding per 5 minuten gebruik je 288
De methodiek zou nu wel duidelijk moeten zijn

 

[shalhevet]

Wow, hartelijk dank allemaal.

Moet eerlijk bekennen dat ik nooit goed was met breuk en met rekenen. Denk dat daarom ben ik zo'n freak van Excel geworden, het programma rekent alles zelf en hoef ik geen zorgen te maken hahaha.

Maar..... in een tweede bestand heb ik dezelfde tijden maar dan zonder kolom F (pauze van 30 min). Normaliter gebruik ik in dat bestand de formule:

=ALS((D25-C25)*24-0,5 > 0;(D25-C25)*24-0,5;"")

Deze trekt zelf al de 30 min pauze van de totale uren.

Hoe kan ik de formule van jullie zodat het ook voor dat bestand werkt?

Ik heb de formule van HSV geprobeerd aan te passen:

=ALS($D25-$C25)*24-0,5>0;AFRONDEN.N.VEELVOUD($D25-$C25;1/96);""

maar dat werkt niet.

Ook de formule van Peter heb ik geprobeerd:

=ALS((D25-C25)*24-0,5 > 0;AFRONDEN((D25-C25)*24/0,25;0)*0,25/96;"")

maar hiermee krijg ik, als ik de volgende tijden als voorbeeld neem:

begin tijd = 6:00 uur
Eind tijd = 15:30 uur
Pauze = 30 min

2:22:30 als totaal gewerkte uren.

Waar gaat het mis?

 

[HSV]

1 staat in Excel voor 24 uur.
0,5 = 12 uur.
1 delen door 24 = 1 uur in tijd van Excel (opmaak op tijd zetten).
0:30 uur = delen door 48.

Hier wordt er op een kwartier afgerond (1/96).

=ALS($E$21-$D$21-1/48>0;AFRONDEN.N.VEELVOUD($E$21-$D$21-1/48;1/96);"")

 

[Peter B]

Ook de formule van Peter heb ik geprobeerd:

=ALS((D25-C25)*24-0,5 > 0;AFRONDEN((D25-C25)*24/0,25;0)*0,25/96;"")

maar hiermee krijg ik, als ik de volgende tijden als voorbeeld neem:

begin tijd = 6:00 uur
Eind tijd = 15:30 uur
Pauze = 30 min

2:22:30 als totaal gewerkte uren.

Waar gaat het mis?

Doordat je of 0,25/24 moet gebruiken als factor of 1/96. Dus niet 0,25/96 ...

 

[Peter B]

Tja, we hebben een verschil van een half uur.
Zie bestandje.

Oeps. Ben het half uur pauze vergeten in de uiteindelijke formule ...

 

[shalhevet]

Ok, dat is duidelijk zo.

Maar nu kom ik het volgende probleem tegen:

Omdat ik de getalnotatie op "tijd" zet worden de aantal uren van het hele week niet goed doorberekend.

Bijv. als de hele week 8 uur per dag gewerkt is, dat moet aan het eind van de week 40 uur staan.

Als ik de simpele formule:

=SOM(E25:E31)

gebruik krijg ik een totaal van:

(getalnotatie standaard) 2,3333333
(getalnotatie getal) 2,33
en ga zo door.

Hoe kan ik dit oplossen? Moet ik een andere som formule gebruiken? of de getalnotatie aanpassen?

 

[popipipo]

Zet het celformaat eens op :mm

 

[shalhevet]

ohhh, tja, je moet het ook net weten

Hartstikke bedankt iedereen die de tijd en moeite hadden genomen om echt het e.e.a. uit te leggen en te helpen!

Super :thumb: