!! Totaal in Inkomsten & Uitgaven !!

[kingowner]

Goedenmorgen,

Ik had paar weken geleden gevraagd hoe ik maanden en jaartalen kon scheiden in mijn Inkomsten & Uitgaven bestand.
Ik wou daar graag nog een aanvulling op zodat ik ook kan kiezen tussen het rijtje maanden of jaartal dat ik Totaal kan kiezen of doormiddel van een button.
Ik vroeg mij af hoe ik dat kon maken.

Ik hoop dat iemand me kan helpen.

Bestand bijgevoegd.

Groet,

Bekijk bijlage Financieel overzicht V.FEB2016(cobbe) SPLITS MAANDEN en JAREN.xlsx

 

[Cobbe]

of doodmiddel van een button.

Wij leveren hier geen 'doodmiddel' op simpele vraag.

 

[kingowner]

*Doormiddel Excuses

 

[MarcelBeug]

Ik heb "Totaal" toegevoegd boven het rijtje maanden en de formules iets aangepast.
Het zijn nu wel matrixformules geworden, d.w.z. de invoer bevestigd met Ctrl+Shift+Enter.
Als het goed is, bedoelde je zoiets.

 

[kingowner]

Ja ik vond het heel erg lastig!, maar hij werkt inderdaad nog niet

 

[MarcelBeug]

Nieuwe bijlage geplaatst in post #4.

 

[kingowner]

Bedankt! Wat bedoeld u trouwens met ctrl shift enter en zou het ook mogelijk zijn als je Totaal invoert dat tekst van jaartalen even verdwijnt en weer zichtbaar word als je gewoon weer maanden aangeeft.

Groet,

Nogmaals bedankt!

 

[kingowner]

ooh zo het is Totaal van het jaartal ik begrijp wat heeft aangepast alleen kun je bijvoorbeeld ook totaal van alle jaartalen zien?

 

[MarcelBeug]

Ik heb ongeveer hetzelfde gedaan voor het jaartal, maar dan met "generaal" i.p.v. "Totaal".
Je kunt een "Totaal generaal" opvragen of een bepaalde maand voor alle jaren (bijv. "januari generaal").

 

[kingowner]

Krijg het niet voor elkaar

 

[kingowner]

om het in het iets ander bestand te krijgen dan werk het niet zegt die

 

[kingowner]

Bestand is te groot het als bijlage te sturen
=SOMPRODUCT((ALS($H$5="Alles";1;MAAND(tblUitgaven[Datum])=MAAND($H$5)))*(ALS($I$5="Alles";1;JAAR(tblUitgaven[Datum])=$I$5))*(tblUitgaven[Categorie]=D10)*(tblUitgaven[Inkomsten]))

Dit is toch goed maar het werkt niet

H5 daar staan de maanden
I5 daar staan de jaren

Totaal veranderd in Alles
generaal veranderd in Alles

Zo moet die zijn alleen snap niet waarom die niet werkt..

 

[kingowner]

Hierbij de bijlage

 

[MarcelBeug]

Hoogstwaarschijnlijk ben je de Ctrl+Shift+Enter vergeten na het intypen van de formule.
Er komen dan automatisch accolades om de formule heen te staan.
{=SOMPRODUCT((ALS($H$5="Alles";1;MAAND(tblUitgaven[Datum])=MAAND($H$5)))*(ALS($I$5="Alles";1;JAAR(tblUitgaven[Datum])=$I$5))*(tblUitgaven[Categorie]=D10)*(tblUitgaven[Inkomsten]))}

Als die er niet staan, dan terug in de formule-editor (F2) en alsnog op Ctrl+Shift+Enter drukken.

 

[MarcelBeug]

Geen matrix- maar bijzondere formules

Bijgaand nog een versie met gewone formules, in die zin dat het geen matrixformules zijn. Verder zijn ze best bijzonder...

Ik zal het dus maar even toelichten aan de hand van de formule in E5:

=SOMPRODUCT((($E$1="Totaal")*(tblUitgaven[Datum]>0)+(($E$1<>"Totaal")*(MAAND(tblUitgaven[Datum])=ALS.FOUT(MAAND($E$1);0))))*(($H$1="generaal")*(tblUitgaven[Datum]>0)+($H$1<>"generaal")*(JAAR(tblUitgaven[Datum])=$H$1))*(tblUitgaven[Categorie]=D5)*(tblUitgaven[Uitgaven]))

De truc zit hem erin dat er 2 selecties op maand plaatsvinden waarvan de uitkomsten bij elkaar worden opgeteld in het deel:
(($E$1="Totaal")*(tblUitgaven[Datum]>0)+(($E$1<>"Totaal")*(MAAND(tblUitgaven[Datum])=ALS.FOUT(MAAND($E$1);0))))

Als $E$1="Totaal" geldt de (fake) test tblUitgaven[Datum]>0, hetgeen allemaal WAARs oplevert, oftewel enen.
Als $E$1<>"Totaal" dan geldt de echte test op maand.
Omdat bij elke waarde van $E$1 elk onderdeel van de formule wordt uitgevoerd, levert MAAND($E$1) een fout op als $E$1 = "Totaal".
Vandaar de ALS.FOUT constructie. De waarde-indien-fout (0) is niet zo relevant omdat dat stukje formule dan toch allemaal nullen oplevert.

Voor het jaartal is een zelfde constructie toegepast, alleen is daar ALS.FOUT niet nodig.

 

[MarcelBeug]

Iets simpeler

De truc zit hem erin dat er 2 selecties op maand plaatsvinden waarvan de uitkomsten bij elkaar worden opgeteld in het deel:
(($E$1="Totaal")*(tblUitgaven[Datum]>0)+(($E$1<>"Totaal")*(MAAND(tblUitgaven[Datum])=ALS.FOUT(MAAND($E$1);0))))

Als $E$1="Totaal" geldt de (fake) test tblUitgaven[Datum]>0, hetgeen allemaal WAARs oplevert, oftewel enen.

Dat kan simpeler: $E$1="Totaal" is al voldoende, oftewel de hele formule in E5:

=SOMPRODUCT((($E$1="Totaal")+(($E$1<>"Totaal")*(MAAND(tblUitgaven[Datum])=ALS.FOUT(MAAND($E$1);0))))*(($H$1="generaal")+($H$1<>"generaal")*(JAAR(tblUitgaven[Datum])=$H$1))*(tblUitgaven[Categorie]=D5)*(tblUitgaven[Uitgaven]))

 

[kingowner]

Helemaal Top bedankt !!!