• Privacywetgeving
    Het is bij Helpmij.nl niet toegestaan om persoonsgegevens in een voorbeeld te plaatsen. Alle voorbeelden die persoonsgegevens bevatten zullen zonder opgaaf van reden verwijderd worden. In de vraag zal specifiek vermeld moeten worden dat het om fictieve namen gaat.

eerste datum in 2023 weergeven

Status
Niet open voor verdere reacties.
M

mmnijssen

Gebruiker
Lid geworden
17 okt 2008
Berichten
22
Hallo,

ik heb 3 tabellen, een tabel met datum uit de geschiedenis, een tweede tabel met de datum uit de huidige data, in de derde kolom moet een formule staan welke naar de eerste 2 tabellen kijkt en vervolgens de eerste datum vermeld in 2023.
Wie o wie kan mij helpen?

Alvast bedankt!
 

Bijlagen

Laatst bewerkt:
een van de vele mogelijkheden:
Code: 
=ALS(JAAR(Tabel1[@datum])=2023;MIN(Tabel1[@datum];Tabel2[@datum]);Tabel2[@datum])
 
Nog eentje dan:
Code: 
=MIN(Tabel2[@datum];Tabel1[@datum]*(1+10*(Tabel1[@datum]<44927)))
 
Bedankt voor beide antwoorden, ze beide werken prima. Ik heb alleen een fout gemaakt, de nummers in tabel 1 staan niet in dezelfde volgorde als tabel 2 en 3, er zal dus iets van een zoekformule in verwerkt moeten worden
 

Bijlagen

Dan kan het met power query.
 

Bijlagen

Laatst bewerkt:
Misschien zoiets qua Excel 365 formule?
Code: 
=LET(x;ALS.FOUT(VERT.ZOEKEN([@nr];Tabel1;2;0);0);y;ALS.FOUT(VERT.ZOEKEN([@nr];Tabel2;2;0);0);k;ALS(JAAR(x)=2023;x;EXP(99));l;ALS(JAAR(y)=2023;y;EXP(99));MIN(k;l))
 
of
Code: 
=LET(nr;VERT.STAPELEN(Tabel1[nr];Tabel2[nr]);datum;VERT.STAPELEN(Tabel1[datum];Tabel2[datum]);MIN(FILTER(datum;(nr=Tabel3[@nr])*(JAAR(datum)=2023))))
 
Ook leuk; dynamisch.

Code: 
=LET(nr;VERT.STAPELEN(Tabel1[nr];Tabel2[nr]);datum;VERT.STAPELEN(Tabel1[datum];Tabel2[datum]);x;SORTEREN.OP(HOR.STAPELEN(nr;datum);datum);INDEX(INDEX(x;;2);VERGELIJKEN(Tabel3[nr];ALS(JAAR(INDEX(x;;2))=2023;INDEX(x;;1);"");0)))
 
Het lijkt een heel simpel probleem, tot je ermee bezig gaat...
 
Ik kwam een heel eind met de volgende matrixformule:

PHP: 
=MIN(IF((Tabel2[nr]=J5)*(YEAR(Tabel2[datum])=2023);Tabel2[datum]);IF((Tabel1[nr]=J5)*(YEAR(Tabel1[datum])=2023);Tabel1[datum]))
 
Status
Niet open voor verdere reacties.
                    Steun ons                    

Nieuwste berichten

Terug
Bovenaan Onderaan