Datum verwijderen uit string

[Conseclusie]

Heeft iemand een korte UDF (of andere oplossing) voor het volgende probleempje:
In een cel staat de volgende string:

"Activiteit 14-07-2016 13:00 - 14-07-2016 17:00"

Ik wil de beide datums uit de string verwijderen, dus:

"Activiteit 13:00 - 17:00".

De datum is variabel, evenals de activiteit. Datum staat dus nooit op een vaste positie, maar is wel steeds dd-mm-jjjj.
Met de Like-operator is het wel eenvoudig vast te stellen of de string een datum bevat, maar om die datum eruit te krijgen blijkt lastig.

 

[alphamax]

Een UDF met RegExp (niet makkelijk maar zeer krachtig)

Public Function DatumVerwijderen(strString As String) As String
    With CreateObject("VBScript.RegExp")
        .Global = True
        .Pattern = "\d{1,2}-\d{1,2}-\d{1,4}"
        DatumVerwijderen = .Replace(strString, "")
        .Pattern = "\ +"
        DatumVerwijderen = .Replace(DatumVerwijderen, " ")
    End With
End Function

 

[snb]

sub M_snb()
   msgbox F_snb("Activiteit 14-07-2016 13:00 - 14-07-2016 17:00")
End sub

function F_snb(c00)
   F_snb= replace(join(filter(split(replace(c00," - ","~")),"-",0)),"~"," - ")
End Function

of

function F_snb(c00)
   F_snb= join(filter(split(c00),"-2",0))
End Function

Zowel krachtig als simpel

 

[Conseclusie]

@alphamax: werkt als een klok. Mooie (en voor mij leerzame) oplossing.
@snb: altijd genieten van je ultra-compacte oplossingen. :thumb: Er zit nog een klein dingetje scheef: resultaat is nu "activiteit 17:00". De aanvangstijd is er dus ook afgevallen.

 

[alphamax]

Het ligt aan de invoer, als het door verschillende personen wordt ingevoerd kan je vanalles verwachten.
datums met of zonder voorloopnullen, jaren met of zonder eeuwaanduiding, spaties tussen de getallen en streepjes of niet, datum voor of achter de tijd etc. etc.

 

[snb]

@snb: altijd genieten van je ultra-compacte oplossingen. :thumb: Er zit nog een klein dingetje scheef: resultaat is nu "activiteit 17:00". De aanvangstijd is er dus ook afgevallen.

Bij de tweede -kortste- versie toch niet ?

En met deze loopt het nu ook soepel:

Function F_snb(c00)
   F_snb = Replace(Join(Filter(Split(Replace(c00, " - ", " ~ ")), "-", 0)), "~", "-")
End Function

Misschien is deze ook wel aardig:

Function F_snb(c00)
   F_snb = Mid(Join(Filter(Split(":" & c00), ":")), 2)
End Function

 

[Conseclusie]

Klopt inderdaad! Had die tweede over het hoofd gezien. Bedankt!
(en alphamax bedankt voor de extra toelichting)

 

[AlexCEL]

Hier nog een formule-variant:

=LINKS(A1;VIND.SPEC("-**-";A1)-3)&SPATIES.WISSEN(DEEL(A1;9+VIND.SPEC("-**-";A1);5)&" - "&RECHTS(A1;5))

 

[snb]

Of dan:

="Activiteit " &MID(A1;SEARCH(":";A1)-2;8) & RIGHT(A1;5)

 

[AlexCEL]

Of dan:

="Activiteit " &MID(A1;SEARCH(":";A1)-2;8) & RIGHT(A1;5)

...de datum is variabel, evenals de activiteit...

 

[Conseclusie]

@AlexCEL: werkt inderdaad prima; thx!
@snb: zal zonder twijfel ook werken; de activiteit varieert echter.

 

[snb]

Dan heb je een andere vraag dan in #1 geformuleerd.
En de datum doet er niet toe.

 

[Conseclusie]

Dan begrijpen we elkaar wellicht verkeerd; in #1 stond wel degelijk:

De datum is variabel, evenals de activiteit.

 

[alphamax]

Staat de datum altijd voor de tijd?