Gegevens transporteren van ene naar andere blad

[Snulk]

Zie het bijgevoegde bestand. Dit is Excel 365. Ik wil in tabblad Werkprogramma de gegevens die horen bij (in dit geval) Behandelruimte en Tapijt overhevelen uit het tabblad Data Nieuw.
Dus dat er in I6 automatisch 203 komt te staan en in J6 52 enz.
Ik dacht al aan Als, maar dat worden wel erg veel geneste alsjes. Ook met X-zoeken kom ik er niet uit....

Wie wil helpen?

Groeten,
Jos

 

[jverkerk]

I6

=X.ZOEKEN($E6&$F6;'Data nieuw'!B:B&'Data nieuw'!C:C;'Data nieuw'!G:G)

J6

=X.ZOEKEN($E6&$F6;'Data nieuw'!B:B&'Data nieuw'!C:C;'Data nieuw'!H:H)

 

[cow18]

gebruik van volledige kolommen (+1.048.000 cellen) in je X.Zoeken.
Maak er een gestructureerde tabel van en alles is zoveel eenvoudiger en sneller !

 

[Snulk]

Perfect! En dan alleen wat vastzetten met F4 en kopiëren maar. Dankjewel

Bericht automatisch samengevoegd: 11 dec 2025

gebruik van volledige kolommen (+1.048.000 cellen) in je X.Zoeken.
Maak er een gestructureerde tabel van en alles is zoveel eenvoudiger en sneller !

Weet ik, tabellen zijn veel handiger, maar het is niet mijn tabel. De gebruiker wil het graag zo houden

 

[cow18]

dan maak je wat gedefinieerde namen aan zoals "ruimte" en "vloer" en gebruik je een hulpkolommetje om de gepaste rij maar 1 keer te hoeven berekenen.

 

[JEC.]

Of noteer zo om tot laatste gevulde regel te zoeken

B:.B

 

[edmoor]

Maar dan zonder die punt voor de 2e B.

 

[JEC.]

Die punt voor de tweede B zorgt er juist voor dat het bereik niet verder kijkt dan de laatst gevulde cel

 

[edmoor]

Ok.
Dat wist ik niet, nooit zo gebruikt.
Maak ik er verder geen punt van

 

[Warme bakkertje]

@edmoor
De TrimRange functie of dot werkt dan ook enkel in O365.

 

[edmoor]

Thanks.
Ik gebruik Office Professional 2021.

 

[jverkerk]

Als @Snulk tevreden is dan kan deze ook als opgelost gezet worden.
Ik zou er ook liever gestructureerde tabellen van maken, de kopteksten zijn een beetje groot of veel.

 

[Snulk]

Als @Snulk tevreden is dan kan deze ook als opgelost gezet worden.
Ik zou er ook liever gestructureerde tabellen van maken, de kopteksten zijn een beetje groot of veel.

zeer tevreden, dus zal als opgelost markeren.

 

[Snulk]

Beste mensen, voor degene voor wie ik dit gemaakt heb met jullie zeer deskundige hulp, vraagt nog iets extra's. Als dat opgelost is dan is haar formulier klaar!
Zie bijgaand bestand. Op H6 staat de formule nu en die werkt! Maar...ik wil dat als ik de formule kopieer naar beneden er geen nullen verschijnen, ook geen #NB maar leeg blijft. Ik dacht het met ALS.FOUT en dan "" opgelost te hebben. Toch verschijnen er 0.
Tweede vraag: als er in G-kolom 208 komt (zoals nu G6 en G7) dan moet in de rij erachter de 255 veranderen in 208. En als er in G-kolom 104 komt (G9 en G11) dan moet in de rij erachter de 255 veranderen in 104.
Dank alvast,
Jos

 

[jverkerk]

=ALS(X.ZOEKEN($E6&$F6;'Data nieuw'!$B:$B&'Data nieuw'!$C:$C;'Data nieuw'!F:F;"")=0;"";X.ZOEKEN($E6&$F6;'Data nieuw'!$B:$B&'Data nieuw'!$C:$C;'Data nieuw'!F:F;""))

=LET(resultaat; X.ZOEKEN($E6&$F6;'Data nieuw'!$B:$B&'Data nieuw'!$C:$C;'Data nieuw'!F:F;""); ALS(resultaat=0;"";resultaat))

 

[HSV]

Een Spill-formule; in een keer per kolom.

=ALS.FOUT(--INDEX('Data nieuw'!F8:.F1000&"";X.VERGELIJKEN(E6:.E1000&F6:.F1000;'Data nieuw'!B8:.B1000&'Data nieuw'!C8:.C1000));"")

Het kan ook voor de gehele tabel in een keer.

=ALS.FOUT(--KIES.RIJEN('Data nieuw'!F8:.Y1000&"";X.VERGELIJKEN(E6:.E1000&F6:.F1000;'Data nieuw'!B8:.B1000&'Data nieuw'!C8:.C1000));"")

 

[Snulk]

Wow, indrukwekkend. Ga ik proberen. Hebben jullie ook iets voor de tweede vraag? Dat die waarde van 255 moet veranderen

 

[HSV]

Zoiets als bestand in bijlage?

 

[Snulk]

HSV dit is echt fenomenaal!!!
Deze ga ik gebruiken. Exact wat ik (zij) wil. Super. Nog 1 vraag: ik zie dat er blauw kadertje omheen komt als ik er in klik en dat de formule lichtgrijs is. Is dat een maxtrix-formule? Kun je m nog aanpassen dat ze zelf die formule ook naar beneden en rechts kan kopiëren? Nu gaat dat niet. Vastzetten...?

 

[JEC.]

Met die matrix formules zorg je ervoor dat je dat slepen niet meer hoeft te doen. In principe staat de formule maar in één cel (de cel in de linker bovenhoek van de matrix). Hier nog een variatie:

=LET(t;'Data nieuw'!A8:.W1000;fr;G6:.G1000;res;CHOOSEROWS(DROP(t;;5);XMATCH(E6:.E1000&F6:.F1000;INDEX(t;;2)&INDEX(t;;3)));IF(REGEXTEST(fr;"104|208")*(res=255);fr;res&""))