Gegevens verzamelen van ander werkblad

[Bartslife]

Hallo,

Recentelijk vond ik een werkende script van WiGi op dit forum. Hieronder de aangepaste versie die ik gebruikte.

Nu creerde dit script prima een reeks gegevens op het tabblad: "Verzameling".

Nu ben ik echter opzoek naar een mogelijkheid om de locatie van de geproduceerde reeks beter te bepalen. Ik wil de resultaten graag (zie voorbeeld) op sheet: verzameling (2) en dan in de cellen: B8 (t/m H8).

Kan iemand me vertellen hoe ik het onderstaande script moet aanpassen?

En mocht het dan niet teveel gevraagd zijn, zou het mogelijk zijn om alleen de omschrijving en het totaal bedrag per omschrijving mee te pakken?

Sub VindWAAR()

Dim c As Range
Dim firstAddress As String

With Sheets("LB-8474").Range("LB_GEVULD")
Set c = .Find(1, LookIn:=xlValues)
If Not c Is Nothing Then
firstAddress = c.Address
Do
c.EntireRow.Copy Sheets("Verzameling").Range("A" & Rows.Count).End(xlUp).Offset(1)


Set c = .FindNext(c)
Loop While Not c Is Nothing And c.Address <> firstAddress
End If
End With

End Sub

 

[Wigi]

Sub VindWAAR()
  
    Dim c As Range
    Dim firstAddress As String
    
    With Sheets("LB-8474").Range("G2:G76")
        Set c = .Find(1, LookIn:=xlValues)
        If Not c Is Nothing Then
            firstAddress = c.Address
            Do
                [B]c.offset(0,-6).Resize(1,7).Copy Sheets("Verzameling (2)").Range("B" & Rows.Count).End(xlUp).Offset(1)[/B]
                Set c = .FindNext(c)
            Loop While Not c Is Nothing And c.Address <> firstAddress
        End If
    End With

End Sub

Wigi

 

[Wigi]

Bovenstaande code van mij werkt. Maar als het over heel wat regels gaat, zou ik deze code gebruiken:

http://www.contextures.com/xlautofilter03.html#Copy

Wigi

 

[Bartslife]

Geweldig!

Is er een snelle mogelijkheid om de doel-range altijd in een specifieke cel te laten starten.

Nu is het zo dat code zoekt naar de eerst volgende lege regel en die "B" zorgt ervoor dat er nu in de 2e kolom wordt gestart.

Ik wil de doel-range namelijk opnemen tussen een aantal andere gegevens verzameld vanaf andere sheets?

Ondertussen kijk ik natuurlijk even naar de website die je gelinkt hebt!

 

[Wigi]

Sub VindWAAR()
  
    Dim c As Range
    Dim firstAddress As String
    Dim rStartCel As Range
    Dim lAantal As Long
    
'==================================
'verander indien nodig
    Set rStartCel = Sheets("Verzameling (2)").Range("B10")
'==================================
    
    With Sheets("LB-8474").Range("G2:G76")
        Set c = .Find(1, LookIn:=xlValues)
        If Not c Is Nothing Then
            firstAddress = c.Address
            Do
                lAantal = lAantal + 1
                c.Offset(0, -6).Resize(1, 7).Copy rStartCel.Offset(lAantal - 1)
                Set c = .FindNext(c)
            Loop While Not c Is Nothing And c.Address <> firstAddress
        End If
    End With

End Sub

Wigi

 

[Bartslife]

Super, ik gebruik dit forum nu voor de tweede keer en wederom heb je binnen no-time een antwoord voor me klaar!

Thanx!

Wilco

 

[Wigi]

Super, ik gebruik dit forum nu voor de tweede keer en wederom heb je binnen no-time een antwoord voor me klaar!

Thanx!

Wilco

Graag gedaan, blij dat je geholpen bent.

Wigi