Mbv vba rij- en kolomvelden verwijderen uit draaitabel

[linkav]

Hallo,

Mbv van onderstaande code wil ik velden die geselecteerd zijn al kolom- of rij-velden verwijderen uit de draaitabel. Ik krijg steeds een foutmelding, zie afb-1.jpg

Omdat ik er zelf niet uitkom wil ik beroep doen op jullie kennis!

Alvast bedankt!!!

Sub RemoveAllFieldsRow()
Dim pt As PivotTable
Dim pf As PivotField
Dim lRmv As Long

Set pt = ActiveSheet.PivotTables(1)

For Each pf In pt.RowFields
  lRmv = vbYes
  If pf.Name = "Data" Or pf.Name = "Values" Then
    lRmv = MsgBox("Click Yes to remove Values field from Row area." _
      & vbCrLf _
      & "Click No to keep the Values field.", _
        vbQuestion + vbYesNo, "Remove Values?")
  End If
  If lRmv = vbYes Then
    pf.Orientation = xlHidden
  End If
Next pf

End Sub

 

[jkpieterse]

Werkt prima bij mij?!?

 

[linkav]

Hallo jan Karel,

Bedankt voor je reactie.

Spijtig genoeg werkt het bij mij niet. Ik heb het ook getest met een pivottable gemaakt van data die op een excel-tabblad staan, maar bij mij staan komen ze uit een tabel (SQL-server cube).

 

[jkpieterse]

Aha, kennelijk een OLAP kubus of powerpivot draaitabel. Je moet de CubeFields doorlopen en pf declareren als CubeField.

 

[linkav]

Ga ik testen!!!

Bedankt voor de info!

 

[snb]

Voor nieuwelingen onder ons: voeg een bestand toe: zie http://www.helpmij.nl/forum/announcement.php?f=5

 

[linkav]

Beste SNB,

Heeft dat zin om bij dit probleem een bestand toe te voegen? De Excel is gekoppeld aan een SQL-Server en ik weet haast zeker dat de meeste menden dat niet hebben staan, laat staan op dezelfde manier een cube gedefinieerd hebben zoals bij de gebruiker...

Ik zou anders zeker een bestand toegevoegd hebben...

 

[snb]

Deze gegevens had je dan in de beginvraag kunnen zetten; nu kwam JKP er pas inferentieel achter.

 

[linkav]

Dit is de code geworden en werkt!

Allen bedankt voor de reactie.

Sub RemoveAllFieldsRow()
Dim pt As PivotTable
Dim pf As CubeField

Set pt = ActiveSheet.PivotTables(1)

    Set pt = ActiveSheet.PivotTables(1)
    
    For Each pf In pt.CubeFields
        If pf.Orientation = 1 Then
            pf.Orientation = xlHidden
        End If
    Next pf
End Sub

Sub RemoveAllFieldsCol()
Dim pt As PivotTable
Dim pf As CubeField

    Set pt = ActiveSheet.PivotTables(1)
    
    For Each pf In pt.CubeFields
        If pf.Orientation = 2 Then
            pf.Orientation = xlHidden
        End If
    Next pf
End Sub