resultaten uit VBA Project naar beveiligde sheet exporteren?

[Tijger81]

Bekijk bijlage Printlijst_invoeren.xls


Op het blad invoer, wordt informatie door studenten ingevoerd. En op tabblad Bestand komen de resultaten.
Nu willen we echter de sheet Bestand beveiligen met een wachtwoord alleen dan komt er een foutmelding als er in sheet Invoer op Invoeren wordt geklikt
met het bericht dat sheet Bestand tegen schrijven beveiligd is. Hoe kan ik ervoor zorgen dat de lijst in sheet Bestand toch aangevuld kan worden vanuit sheet Invoer, terwijl sheet bestand beveiligd is met een wachtwoord???
Dit hebben we al geprobeerd:
Maar werkt niet

Sheets("bestand").Select
    .Unprotect Password:="tijger"
    Rows("3:3").Select
    Selection.Insert Shift:=xlDown
    Range("A9").Select
    Sheets("Invoer").Select
    Range("A9:I9").Select
    Selection.Copy
    Sheets("bestand").Select
    Range("A3").Select
    ActiveSheet.Paste
    Range("A3").Select
    Sheets("Invoer").Select
    Range("A9") = Range("A9")
    Application.CutCopyMode = False
    Range("B9:I9").ClearContents
    Range("A1").Select

 

[pasan]

Voldoet deze?

Sub toevoeg()
Application.ScreenUpdating = False
If Worksheets("invoer").Range("A9") = "" Then Exit Sub
Worksheets("bestand").Unprotect Password:="invoer" 'pas het wachtwoord aan of niet

 With Sheets("bestand")
  .Rows(3).Insert Shift:=xlDown
   Worksheets("invoer").Range("A9:I9").Copy .Range("A3:I3")
   Worksheets("invoer").Range("A9:I9").ClearContents
 End With
 
Worksheets("bestand").Protect Password:="invoer"  'pas het wachtwoord aan als deze maar zelde is als boven
Application.ScreenUpdating = True
End Sub

 

[Tijger81]

Dank je voor je antwoord.
We hebben ondertussen al een oplossing gevonden alleen nu zoeken we nog iets om na het Protecten van het tabblad "bestand" het te verbergen.
Bij de volgende invoer moet het tabblad zichtbaar worden zodat de gegevens ingevoerd kunnen worden. Of kan dat ook als hij onzichtbaar?

 

[pasan]

ja dat kan ook als hij onzichtbaar is ik zou zeggen probeer het gewoon

 

[jeroenrr]

We zijn weer een paar stappen verder. Nu hebben we bij enkele cellen in geselecteerde gebied een dropdownmenu toegevoegd (Data>Validation>list). De data die gebruikt wordt bij de keuzes van de lijst staan buiten de selectie die in het onderstaande code vermeld staan. orghineel

De onderstaande code bied nu de mogelijkheid om de tekst die door studenten is ingevoerd te verplaatsen naar het andere tabblad. Helaas neemt hij de opmaak over van het orginele tabblad waardoor de data validation nog steeds aanwezig is. Hierdoor geeft hij bij de gekopieerde tekst ook een dropdownmenu weer. Deze is echter leeg gezien we in het andere tabblad geen lijst hebben opgesteld. We willen daarom de regel ActiveSheet.Paste zo veranderen dat hij het plakken via pastespecial doet en dus de opmaak niet mee kopieert. Hierbij zouden we de ActiveSheet.Paste moeten vervangen door ActiveSheet.PasteSpecial xlPasteValues. Echter werkt deze regel niet. Moet ik nog wat toevoegen bij de range om de selectie beter te maken?

Sub Toevoegen()
    'Onderste regels zorgen er voor dat het tabblad bestand zichtbaar en bewerkbaar wordt.
    Sheets("bestand").Visible = True
    Sheets("bestand").Select
    ActiveSheet.Unprotect Password:="tijger"
    
    'Tekst van invoer naar bestand kopieren
    Rows("3:3").Select
    Selection.Insert Shift:=xlDown
    Range("A9").Select
    Sheets("Invoer").Select
    Range("A9:I9").Select
    Selection.Copy
    Sheets("bestand").Select
    Range("A3").Select
    ActiveSheet.Paste
    Range("A3").Select
    Sheets("Invoer").Select
    Range("A9") = Range("A9")
    Application.CutCopyMode = False
    Range("B9:I9").ClearContents
    Range("A1").Select
    Sheets("bestand").Select
    
    'Activeren van de beveiliging en het onzichtbaar maken van het tabblad bestand
    ActiveSheet.Protect Password:="tijger"
    ActiveSheet.Visible = False
    Sheets("Invoer").Select
End Sub

 

[pasan]

Probeer deze is je kunt het blad "bestand" gewoon verbergen als je dat wil

Sub toevoeg()
Application.ScreenUpdating = False
If Worksheets("invoer").Range("A9") = "" Then Exit Sub
Worksheets("bestand").Unprotect Password:="invoer" 'pas het wachtwoord aan

 With Sheets("bestand")
  .Rows(3).Insert Shift:=xlDown
   Worksheets("invoer").Range("A9:I9").Copy
   With .Range("A3:I3")
    .PasteSpecial xlPasteValues
    .Borders.LineStyle = xlContinuous
    .Interior.Pattern = xlNone
   End With
   Worksheets("invoer").Range("A9:I9").ClearContents
 End With
 
Worksheets("bestand").Protect Password:="invoer"  'pas het wachtwoord aan
Application.ScreenUpdating = True
End Sub

 

[jeroenrr]

Het werkt, heel erg bedankt!

 

[huijb]

Visual Basic is iets anders dan Visual Basic for Applications, VBA is programmeren binnen Office applicaties. Verplaatst naar juiste sectie.