Verticaal zoeken met tekst tussen formules door

[MauriceD]

Goedenavond,

Ik heb een bestand bij dit onderwerp toegevoegd wat ik precies bedoel.
Ik wil tijdens het verticaal zoeken een bepaalde tekst toevoegen met daarna weer een formule verticaal zoeken.
Wie kan mij helpen?

Verder ben ik benieuwd hoe de = index nou precies werkt. Ook dit heb ik als voorbeeld in het bestand gedropt.

Alvast bedankt!

Gr,
Maurice

 

[edmoor]

Dit is je verticaal zoeken functie:

="Nr "&VERT.ZOEKEN(B3;Tabel1[[Pers.nummer]:[Kluis]];4;ONWAAR)&" met kluiscode "&VERT.ZOEKEN(Blad1!B3;Tabel1;5;ONWAAR)

 

[AlexCEL]

En dit is met INDEX/VERGELIJKEN:

="Nr "&INDEX(Tabel2[Kluis];VERGELIJKEN(B17;Tabel2[Pers.nummer];0))&" met kluiscode "&INDEX(Tabel2[[COLOR="#FF0000"][B]xxx[/B][/COLOR]Code];VERGELIJKEN(B17;Tabel2[Pers.nummer];0))

Rode xxx even weghalen na kopiëren in je sheet....

 

[MauriceD]

Dat is snel!
Bedankt edmoor en Alexcel!

En voor mij om het een beetje beter te begrijpen, hoe zouden jullie via index bij kluis het juiste kluisnummer krijgen & bij code het juiste kluiscode krijgen?
Welke formule gebruik je daarvoor? (Zonder tekst dus)

Gr,
Maurice

 

[AlexCEL]

Dat haal je toch gewoon uit de gepresenteerde formule?

Kluisnummer:

=INDEX(Tabel2[Kluis];VERGELIJKEN(B17;Tabel2[Pers.nummer];0))

Idem voor kluiscode.

Met de VERGELIJKEN functie wordt het rijnummer opgezocht waar in de tabel het gezochte personeelsnummer staat. De INDEX functie zoekt met het gevonden rijnummer de bijbehorende kluiscode op.

 

[MauriceD]

Alex top bedankt!
Heb nog een allerlaatste vraag hierover..
Heb weer een bestandje geupload. Hoe zet je met =index een getal om naar een datum, zie voorbeeld.

Kom er niet uit!

Gr,

 

[Cobbe]

Zo misschien:

=INDEX(Tabel3[JA / NEE];VERGELIJKEN(Blad1!F3;Tabel3[Persnr:];0))&" behaald op "&TEKST(INDEX(Tabel3[Datum behaald];VERGELIJKEN($F3;Tabel3[Persnr:];0));"dd/mm/jjjj")

met de tijd erbij:

=INDEX(Tabel3[JA / NEE];VERGELIJKEN(Blad1!F3;Tabel3[Persnr:];0))&" behaald op "&TEKST(INDEX(Tabel3[Datum behaald];VERGELIJKEN($F3;Tabel3[Persnr:];0));"dd/mm/jjjj -- uu:mm")

 

[MauriceD]

De eerste optie is top zonder tijd..
Echter als iemand nu de test niet heeft gedaan dan komt er te staan (NEE behaald op 0/0/1900)
Hoe is dit op te lossen?

Gr,
Maurice

 

[Cobbe]

Zo misschien:

=ALS(INDEX(Tabel3[JA / NEE];VERGELIJKEN(Blad1!F3;Tabel3[Persnr:];0))="Nee";"Test niet geslaagd";INDEX(Tabel3[JA / NEE];VERGELIJKEN(Blad1!F3;Tabel3[Persnr:];0))&" behaald op "&TEKST(INDEX(Tabel3[Datum behaald];VERGELIJKEN($F3;Tabel3[Persnr:];0));"dd/mm/jjjj"))

 

[snb]

Ik zie niet veel leerprogressie bij Maurice.