zoeken in lijst

[RB_online]

Beste forumleden,

ik zit met een, voor mij dan , complexe functie.

Ik heb op blad 1 een bereik van 2 kolommen. zij vormen samen een paar.
OP blad 2 heb ik een lijst met alle mogelijke paren. Nu wil op blad 2 in de cel naast de lijst een opmerking plaatsen die aangeeft dat dit paar al voorkomt in de lijst op blad 1.
De lijst op blad 2 veranderd niet, de lijst op blad 1 wordt steeds bijgewerkt.
Het is wedstrijdschema. zie ook bijlage voor meer duidelijkheid

ik heb al diverse functie geprobeerd maAr ik krijg het niet werkend, o.a. vergelijken, index

 

[Thankyou]

Met deze formule voor in C2 (je kan hem doortrekken naar beneden, moet je alleen je opmaak aanpassen)

=ALS(OF(A2="";B2="");"";ALS(ISGETAL(VERGELIJKEN($A2&$B2;Blad1!$A$1:$A$25&Blad1!$B$1:$B$25;0));"Komt voor";ALS(ISGETAL(VERGELIJKEN($A2&$B2;Blad1!$B$1:$B$25&Blad1!$A$1:$A$25;0));"Komt voor";"")))

en afsluiten met ctrl+shift+enter in plaats van enter.

Succes,

 

[RB_online]

@thankyou

Helaas werkt hij niet goed. Het voorbeeld bestand was tot 10 personen, het echte bestand loopt tot 30 personen.

Van 22 4 maakt hij 224 en gaat deze vergelijken.
Hij maakt van 2 24 echter ook 224 en zegt dan "komt voor".
Dit is dus helaas niet goed.

Misschien een aanpassing?
In ieder geval bedankt voor de poging.

René

 

[RB_online]

Al opgelost.
Elke & vervangen door & " " &.
hierdoor blijft 2 24 altijd 2 24 en 22 4 blijft 22 4 dus altijd verschillend.
Thankyou bedankt voor de geweldige voorzet:thumb:

gr René

ps de formule is dus nu

=ALS(OF(A2="";B2="");"";ALS(ISGETAL(VERGELIJKEN($A2& " " & $B2;Blad1!$A$1:$A$25& " " & Blad1!$B$1:$B$25;0));"Komt voor";ALS(ISGETAL(VERGELIJKEN($A2& " " & $B2;Blad1!$B$1:$B$25& " " & Blad1!$A$1:$A$25;0));"Komt voor";"")))

 

[Thankyou]

Probeer hem zo eens . . .

=ALS(OF(A2="";B2="");"";ALS(ISGETAL(VERGELIJKEN($A2&"-"&$B2;Blad1!$A$1:$A$25&"-"&Blad1!$B$1:$B$25;0));"Komt voor";ALS(ISGETAL(VERGELIJKEN($A2&"-"&$B2;Blad1!$B$1:$B$25&"-"&Blad1!$A$1:$A$25;0));"Komt voor";"")))

Succes,

 

[Thankyou]

Net te laat, zelfde oplossing.

Wil je de vraag nog op opgelost/afgehandeld zetten?

Bedankt,