Zoeken naar deel van tekst in cell

[Friends4U]

Hoi,

Ik probeer te zoeken naar een deel van tekst in een cell.
Als ik deze formule gebruik:

=ALS(ISLEEG(E73);;ALS(M73="Overwerk";24*MAX(0;$E73-$D73);ALS(M73="Vakantie";0;ALS(ISLEEG(A73);0;(24*MAX(0;$E73-$D73)-9,5)))))

En ik Typ in cell M73 het woord Overwerk dan gaat het goed, maar als ik daar iets achter zet dan niet meer. Als ik dan de formule aanpas naar:

=ALS(ISLEEG(E73);;ALS(M73="Overwerk*";24*MAX(0;$E73-$D73);ALS(M73="Vakantie";0;ALS(ISLEEG(A73);0;(24*MAX(0;$E73-$D73)-9,5)))))

Dus met een * achter het woord, dan zou ik verwachten dat Overwerk test óók goedgekeurd zou worden. Maar dit is niet het geval.

Ik zou dus willen dat hij dan triggerd op zowel het woord: Overwerk als een zin beginnende met Overwerk blabla.
Iemand een idee wat ik fout doe?

Groetjes

 

[Senso]

De aanhalingstekens vertellen Excel het gaat om tekst en met tekst bedoelen we elk teken, inclusief getallen, spaties en interpunctie.

Lijkt mij dat dan ook * en ? als tekens gezien worden en niet als parameter.

 

[HSV]

Probeer dit.

=als(isgetal(vind.spec("overwerk";M73));24*max( end de rest van je formule

Anders je bestand plaatsen omdat je meerdere voorwaarden hebt.

 

[AlexCEL]

Of:

=ALS(AANTAL.ALS(M73;"Overwerk*")>0;24*MAX( en de rest van je formule...

Als je een excelvoorbeeld plaatst krijg je een volledige oplossing.

 

[Friends4U]

Ga ik op terugkomen...

 

[Friends4U]

Hierbij een voorbeeld, het gaat nu om rij 16 en 17, de formule in 16 is goed maar in 17 werkt hij niet correct omdat ik wat achter het woord Overwerk wil typen.

 

[AlexCEL]

Ik heb e.e.a. maar wat simpeler gemaakt:

=ALS(OF(A16="";E16="";M16="Vakantie");0;24*MAX(0;$E16-$D16)-9,5*(AANTAL.ALS(M16;"*overwerk*")=0))

Of, zo je wilt:

=ALS(OF(A16="";E16="";M16="Vakantie");0;24*MAX(0;$E16-$D16)-9,5*ISFOUT(VIND.SPEC("overwerk";M16)))

 

[Friends4U]

Dank je wel, ik ga hierop studeren want ik wil het graag snappen

Enne, kun je de formule op L16 dan ook wijzigen zodat hij bij overwerk een 1 plaatst en de rest negeert?

 

[AlexCEL]

In L16 staat geen formule. Alleen een 1 bij "overwerk" is niet zo moeilijk...

=ALS(AANTAL.ALS(M16;"*overwerk*")>0;1;"")

Of moet er iets anders gebeuren?

 

[Friends4U]

Excuus, daar hoort deze formule:

=ALS(M16="Vakantie";0;ALS(OF(SOM(F16+K16)>1;SOM(F16+K16)<-1);"1";"0"))

 

[AlexCEL]

Zie #9?

 

[Friends4U]

Zie #9?

Als ik de formule:

[COLOR=#333333]=ALS(M16="Vakantie";0;ALS(OF(SOM(F16+K16)>1;SOM(F16+K16)<-1);"1";"0"))[/COLOR]

Vervang met:

[COLOR=#333333]=ALS(AANTAL.ALS(M16;"*overwerk*")>0;1;"")[/COLOR]

Ik had hem per ongeluk leeg gelaten daarom postte ik de formule die er origineel stond alwaar jouw formule ingebouwd moet worden.
Ik ga proberen of ik het zelf voor elkaar krijg. Dank voor de hulp tot nu toe~!

 

[Friends4U]

Het is gelukt

Ik heb jouw en mijn formule samengevoegd en dan kom ik op:

=ALS(AANTAL.ALS(M16;"*overwerk*")>0;1;ALS(M16="Vakantie";0;ALS(OF(SOM(F16+K16)>1;SOM(F16+K16)<-1);"1";"0")))

Nogmaals dank voor de hulp!

 

[AlexCEL]

Volgens mij doet deze hetzelfde:

=ALS(OF(AANTAL.ALS(M16;"*overwerk*")>0;ABS(F16+K16)>1);1;0)

 

[Friends4U]

Ik zoek ook naar het woord "Vakantie" he

 

[AlexCEL]

Alleen als (1) het woord overwerk voorkomt in M16, of (2) de som van F16 en K16 groter is dan 1 (of kleiner dan -1) komt er 1 te staan. In ALLE overige situaties is de uitkomst 0 in jouw formule.
Dus: het maakt helemaal niets uit of er nu vakantie staat in M16 of iets anders. Daar doe je niets mee....

 

[Friends4U]

Ok, ik zie het maar snap het niet.
Either way is het resultaat wel wat ik wil